1 | dnl |
---|
2 | AC_INIT(mod_gnutls, 0.7.2) |
---|
3 | OOO_CONFIG_NICE(config.nice) |
---|
4 | MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION |
---|
5 | AC_PREREQ(2.53) |
---|
6 | AC_CONFIG_SRCDIR([src/mod_gnutls.c]) |
---|
7 | AC_CONFIG_AUX_DIR(config) |
---|
8 | |
---|
9 | OOO_MAINTAIN_MODE |
---|
10 | AM_MAINTAINER_MODE |
---|
11 | AC_CANONICAL_TARGET |
---|
12 | # mod_gnutls test suite requires GNU make |
---|
13 | AM_INIT_AUTOMAKE([-Wno-portability]) |
---|
14 | AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in) |
---|
15 | |
---|
16 | AC_SUBST(MOD_GNUTLS_VERSION) |
---|
17 | |
---|
18 | AC_PROG_CC |
---|
19 | AC_PROG_CC_C99 |
---|
20 | AC_PROG_LD |
---|
21 | AC_PROG_INSTALL |
---|
22 | AC_PROG_LIBTOOL |
---|
23 | |
---|
24 | AC_CONFIG_MACRO_DIR([m4]) |
---|
25 | |
---|
26 | AP_VERSION=2.2.0 |
---|
27 | CHECK_APACHE(,$AP_VERSION, |
---|
28 | :,:, |
---|
29 | AC_MSG_ERROR([*** Apache version $AP_VERSION not found!]) |
---|
30 | ) |
---|
31 | |
---|
32 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.4]) |
---|
33 | |
---|
34 | LIBGNUTLS_VERSION=`pkg-config --modversion gnutls` |
---|
35 | |
---|
36 | AC_ARG_ENABLE(srp, |
---|
37 | AS_HELP_STRING([--disable-srp], |
---|
38 | [unconditionally disable the SRP functionality]), |
---|
39 | use_srp=$enableval, use_srp=yes) |
---|
40 | |
---|
41 | # check if the available GnuTLS library supports SRP |
---|
42 | AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"]) |
---|
43 | |
---|
44 | SRP_CFLAGS="" |
---|
45 | if test "$use_srp" != "no"; then |
---|
46 | SRP_CFLAGS="-DENABLE_SRP=1" |
---|
47 | fi |
---|
48 | |
---|
49 | AC_ARG_ENABLE(strict, |
---|
50 | AS_HELP_STRING([--disable-strict], |
---|
51 | [Avoid strict compiler warnings and errors]), |
---|
52 | use_strict=$enableval, use_strict=yes) |
---|
53 | |
---|
54 | STRICT_CFLAGS="" |
---|
55 | if test "$use_strict" != "no"; then |
---|
56 | STRICT_CFLAGS="-Wall -Werror -Wextra" |
---|
57 | fi |
---|
58 | |
---|
59 | AC_MSG_CHECKING([whether to enable SRP functionality]) |
---|
60 | AC_MSG_RESULT($use_srp) |
---|
61 | |
---|
62 | AC_ARG_ENABLE(msva, |
---|
63 | AS_HELP_STRING([--enable-msva], |
---|
64 | [enable Monkeysphere client certificate verification]), |
---|
65 | use_msva=$enableval, use_msva=no) |
---|
66 | AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"]) |
---|
67 | |
---|
68 | MSVA_CFLAGS="" |
---|
69 | if test "$use_msva" != "no"; then |
---|
70 | AC_CHECK_HEADERS([msv/msv.h], [], |
---|
71 | [AC_MSG_ERROR([*** No libmsv headers found!])]) |
---|
72 | AC_SEARCH_LIBS([msv_query_agent], [msv], [], |
---|
73 | [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])]) |
---|
74 | MSVA_CFLAGS="-DENABLE_MSVA=1" |
---|
75 | fi |
---|
76 | |
---|
77 | AC_MSG_CHECKING([whether to enable MSVA functionality]) |
---|
78 | AC_MSG_RESULT($use_msva) |
---|
79 | |
---|
80 | have_apr_memcache=0 |
---|
81 | CHECK_APR_MEMCACHE([have_apr_memcache=1], [have_apr_memcache=0]) |
---|
82 | AC_SUBST(have_apr_memcache) |
---|
83 | |
---|
84 | # Building documentation requires pandoc, which in turn needs pdflatex |
---|
85 | # to build PDF output. |
---|
86 | build_doc=no |
---|
87 | AC_PATH_PROG([PANDOC], [pandoc], [no]) |
---|
88 | if test "$PANDOC" != "no"; then |
---|
89 | AC_PATH_PROG([PDFLATEX], [pdflatex], [no]) |
---|
90 | if test "$PDFLATEX" != "no"; then |
---|
91 | build_doc=yes |
---|
92 | else |
---|
93 | build_doc="html only" |
---|
94 | fi |
---|
95 | fi |
---|
96 | AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"]) |
---|
97 | AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \ |
---|
98 | test "$PDFLATEX" != "no"]) |
---|
99 | |
---|
100 | # Check for Apache binary |
---|
101 | AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin]) |
---|
102 | if test "${APACHE2}" = "no"; then |
---|
103 | AC_MSG_WARN([Neither apache2 nor httpd found in \ |
---|
104 | PATH. Test suite will fail.]) |
---|
105 | fi |
---|
106 | |
---|
107 | MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${SRP_CFLAGS} ${MSVA_CFLAGS} ${APR_MEMCACHE_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}" |
---|
108 | MODULE_LIBS="${APR_MEMCACHE_LIBS} ${LIBGNUTLS_LIBS}" |
---|
109 | |
---|
110 | AC_SUBST(MODULE_CFLAGS) |
---|
111 | AC_SUBST(MODULE_LIBS) |
---|
112 | |
---|
113 | # assign default values to TEST_HOST and TEST_IP if necessary |
---|
114 | : ${TEST_HOST:="localhost"} |
---|
115 | : ${TEST_IP:="[::1]"} |
---|
116 | AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \ |
---|
117 | "make check", must resolve to TEST_IP. The default \ |
---|
118 | is "localhost".]) |
---|
119 | AC_ARG_VAR([TEST_IP], [IP address to use for server instances started by \ |
---|
120 | "make check". The default is the IPv6 loopback address \ |
---|
121 | [::1].]) |
---|
122 | |
---|
123 | AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \ |
---|
124 | doc/Makefile include/mod_gnutls.h]) |
---|
125 | AC_OUTPUT |
---|
126 | |
---|
127 | echo "---" |
---|
128 | echo "Configuration summary for mod_gnutls:" |
---|
129 | echo "" |
---|
130 | echo " * mod_gnutls version: ${MOD_GNUTLS_VERSION}" |
---|
131 | echo " * Apache Modules directory: ${AP_LIBEXECDIR}" |
---|
132 | echo " * GnuTLS Library version: ${LIBGNUTLS_VERSION}" |
---|
133 | echo " * SRP Authentication: ${use_srp}" |
---|
134 | echo " * MSVA Client Verification: ${use_msva}" |
---|
135 | echo " * Build documentation: ${build_doc}" |
---|
136 | echo "" |
---|
137 | echo "---" |
---|