source: mod_gnutls/configure.ac @ 086cea9

debian/masterdebian/stretch-backportsjessie-backportsupstream mod_gnutls/0.7.5
Last change on this file since 086cea9 was 086cea9, checked in by Thomas Klute <thomas2.klute@…>, 3 years ago

Release version 0.7.5

  • Property mode set to 100644
File size: 8.2 KB
Line 
1dnl
2AC_INIT(mod_gnutls, 0.7.5)
3OOO_CONFIG_NICE(config.nice)
4MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION
5AC_PREREQ(2.53)
6AC_CONFIG_SRCDIR([src/mod_gnutls.c])
7AC_CONFIG_AUX_DIR(config)
8
9OOO_MAINTAIN_MODE
10AM_MAINTAINER_MODE
11AC_CANONICAL_TARGET
12# mod_gnutls test suite requires GNU make
13AM_INIT_AUTOMAKE([-Wno-portability])
14AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in)
15
16LT_INIT([disable-static])
17
18AC_SUBST(MOD_GNUTLS_VERSION)
19
20AC_PROG_CC
21AC_PROG_CC_C99
22AC_PROG_LD
23AC_PROG_INSTALL
24AC_PROG_LIBTOOL
25
26AC_CONFIG_MACRO_DIR([m4])
27
28AP_VERSION=2.2.0
29CHECK_APACHE(,$AP_VERSION,
30    :,:,
31    AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
32)
33
34PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.4])
35
36LIBGNUTLS_VERSION=`pkg-config --modversion gnutls`
37
38AC_ARG_ENABLE(vpath-install,
39       AS_HELP_STRING([--enable-vpath-install],
40               [Modify the Apache module directory provided by apxs to \
41               follow --prefix, if necessary. Most users will not want this, \
42               but it is required for VPATH builds including "make \
43               distcheck".]),
44       vpath_install=$enableval, vpath_install=no)
45AM_CONDITIONAL([ENABLE_VPATH_INSTALL], [test "$vpath_install" = "yes"])
46
47AC_ARG_ENABLE(srp,
48       AS_HELP_STRING([--disable-srp],
49               [unconditionally disable the SRP functionality]),
50       use_srp=$enableval, use_srp=yes)
51
52# check if the available GnuTLS library supports SRP
53AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"])
54
55SRP_CFLAGS=""
56if test "$use_srp" != "no"; then
57        SRP_CFLAGS="-DENABLE_SRP=1"
58fi
59
60AC_ARG_ENABLE(strict,
61       AS_HELP_STRING([--disable-strict],
62               [Avoid strict compiler warnings and errors]),
63       use_strict=$enableval, use_strict=yes)
64
65STRICT_CFLAGS=""
66if test "$use_strict" != "no"; then
67        STRICT_CFLAGS="-Wall -Werror -Wextra"
68fi
69
70AC_MSG_CHECKING([whether to enable SRP functionality])
71AC_MSG_RESULT($use_srp)
72
73dnl Optionally disable flock
74AC_ARG_ENABLE(flock,
75        AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \
76        (some exotic architectures don't support it)]),
77        [use_flock=$enableval], [use_flock=yes])
78# Check if flock is available and supports --timeout
79AC_PATH_PROG([FLOCK], [flock], [no])
80AS_IF([test "${FLOCK}" != "no"],
81      [
82        AC_MSG_CHECKING([whether ${FLOCK} supports --timeout])
83        lockfile="$(mktemp)"
84        AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1],
85              [flock_works="yes"], [flock_works="no"])
86        rm "${lockfile}"
87        AC_MSG_RESULT([$flock_works])
88      ],
89      [flock_works="no"])
90# disable flock if requested by user or it doesn't support timeout
91AM_CONDITIONAL([DISABLE_FLOCK],
92               [test "$enable_flock" = "no" || test "$flock_works" = "no"])
93
94dnl Enable test namespaces? Default is "yes".
95AC_ARG_ENABLE(test-namespaces,
96        AS_HELP_STRING([--disable-test-namespaces], [Disable use of network \
97        namespaces to run tests in parallel (some architectures might not \
98        support it)]),
99        [use_netns=$enableval], [use_netns=yes])
100
101# Check if "unshare" is available and has permission to create network
102# and user namespaces
103AC_PATH_PROG([UNSHARE], [unshare], [no])
104AS_IF([test "${UNSHARE}" != "no"],
105      [
106        AC_MSG_CHECKING([for permission to create network and user namespaces])
107        AS_IF([${UNSHARE} --net -r /bin/sh -c \
108                "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1],
109              [unshare_works="yes"], [unshare_works="no"])
110        AC_MSG_RESULT([$unshare_works])
111      ],
112      [unshare_works="no"])
113# decide whether to enable network namespaces
114AS_IF([test "$enable_test_namespaces" != "no" \
115            && test "$unshare_works" = "yes"],
116      [use_netns="yes"], [use_netns="no"])
117AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"])
118# Adjust Apache configuration for tests accordingly: Use pthread mutex
119# and test specific PID files if using namespaces, defaults otherwise.
120AS_IF([test "$use_netns" = "yes"],
121      [MUTEX_TYPE="pthread"; PID_AFFIX="-\${TEST_NAME}"],
122      [MUTEX_TYPE="default"; PID_AFFIX=""])
123AC_SUBST(MUTEX_TYPE)
124AC_SUBST(PID_AFFIX)
125AM_SUBST_NOTMAKE(MUTEX_TYPE)
126AM_SUBST_NOTMAKE(PID_AFFIX)
127
128AC_ARG_ENABLE(msva,
129       AS_HELP_STRING([--enable-msva],
130               [enable Monkeysphere client certificate verification]),
131       use_msva=$enableval, use_msva=no)
132AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"])
133
134MSVA_CFLAGS=""
135if test "$use_msva" != "no"; then
136        AC_CHECK_HEADERS([msv/msv.h], [],
137                         [AC_MSG_ERROR([*** No libmsv headers found!])])
138        AC_SEARCH_LIBS([msv_query_agent], [msv], [],
139                         [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])])
140        MSVA_CFLAGS="-DENABLE_MSVA=1"
141fi
142
143AC_MSG_CHECKING([whether to enable MSVA functionality])
144AC_MSG_RESULT($use_msva)
145
146have_apr_memcache=0
147CHECK_APR_MEMCACHE([have_apr_memcache=1], [have_apr_memcache=0])
148AC_SUBST(have_apr_memcache)
149
150# Building documentation requires pandoc, which in turn needs pdflatex
151# to build PDF output.
152build_doc=no
153AC_PATH_PROG([PANDOC], [pandoc], [no])
154if test "$PANDOC" != "no"; then
155        AC_PATH_PROG([PDFLATEX], [pdflatex], [no])
156        if test "$PDFLATEX" != "no"; then
157                build_doc=yes
158        else
159                build_doc="html only"
160        fi
161else
162        AC_PATH_PROG([MARKDOWN], [markdown], [no])
163        if test "$MARKDOWN" != "no"; then
164                build_doc="html stub"
165        fi
166fi
167AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"])
168AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \
169                               test "$PDFLATEX" != "no"])
170AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \
171                               test "$MARKDOWN" != "no"])
172
173# Check for Apache binary
174AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin])
175if test "${APACHE2}" = "no"; then
176        AC_MSG_WARN([Neither apache2 nor httpd found in \
177                     PATH. Test suite will fail.])
178fi
179
180AC_PATH_PROGS([HTTP_CLI], [curl wget], [no])
181
182MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${SRP_CFLAGS} ${MSVA_CFLAGS} ${APR_MEMCACHE_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}"
183MODULE_LIBS="${APR_MEMCACHE_LIBS} ${LIBGNUTLS_LIBS}"
184
185AC_PATH_PROGS([SOFTHSM], [softhsm2-util softhsm], [no])
186if test "${SOFTHSM}" != "no"; then
187        softhsm_version=$(${SOFTHSM} --version)
188        AS_VERSION_COMPARE([$(${SOFTHSM} --version)], [2.0.0],
189                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [1])],
190                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])],
191                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])])
192fi
193AM_CONDITIONAL([HAVE_SOFTHSM], [test "${SOFTHSM}" != "no"])
194AM_CONDITIONAL([HAVE_SOFTHSM1], [test "${SOFTHSM_MAJOR_VERSION}" = "1"])
195AM_CONDITIONAL([HAVE_SOFTHSM2], [test "${SOFTHSM_MAJOR_VERSION}" = "2"])
196
197AC_SUBST(MODULE_CFLAGS)
198AC_SUBST(MODULE_LIBS)
199
200# assign default values to TEST_HOST and TEST_IP if necessary
201: ${TEST_HOST:="localhost"}
202: ${TEST_IP:="[[::1]] 127.0.0.1"}
203AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \
204                        "make check", must resolve to addresses in TEST_IP. \
205                        The default is "localhost".])
206AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \
207                      started by "make check". The default is \
208                      "[::1] 127.0.0.1". Note that IPv6 addresses must be \
209                      enclosed in square brackets.])
210AM_SUBST_NOTMAKE(TEST_IP)
211
212dnl Allow user to set SoftHSM PKCS #11 module
213AC_ARG_VAR([SOFTHSM_LIB], [Absolute path of the SoftHSM PKCS @%:@11 module to \
214                          use. By default the test suite will search common \
215                          library paths.])
216
217dnl Build list of "Listen" statements for Apache
218LISTEN_LIST="# Listen addresses for the test servers"
219for i in ${TEST_IP}; do
220        LISTEN_LIST="${LISTEN_LIST}
221Listen ${i}:\${TEST_PORT}"
222done
223dnl HTTP ports, only active if TEST_HTTP_PORT is defined
224LISTEN_LIST="${LISTEN_LIST}
225<IfDefine TEST_HTTP_PORT>"
226for i in ${TEST_IP}; do
227        LISTEN_LIST="${LISTEN_LIST}
228        Listen ${i}:\${TEST_HTTP_PORT}"
229done
230LISTEN_LIST="${LISTEN_LIST}
231</IfDefine>"
232AC_SUBST(LISTEN_LIST)
233AM_SUBST_NOTMAKE(LISTEN_LIST)
234
235AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \
236                        doc/Makefile include/mod_gnutls.h \
237                        test/proxy_backend.conf \
238                        test/apache-conf/listen.conf \
239                        test/apache-conf/netns.conf])
240AC_OUTPUT
241
242echo "---"
243echo "Configuration summary for mod_gnutls:"
244echo ""
245echo "   * mod_gnutls version:  ${MOD_GNUTLS_VERSION}"
246echo "   * Apache Modules directory:    ${AP_LIBEXECDIR}"
247echo "   * GnuTLS Library version:      ${LIBGNUTLS_VERSION}"
248echo "   * SRP Authentication:  ${use_srp}"
249echo "   * MSVA Client Verification:    ${use_msva}"
250echo "   * Build documentation: ${build_doc}"
251echo ""
252echo "---"
Note: See TracBrowser for help on using the repository browser.