| 1 | AC_INIT(mod_gnutls, 0.9.0) |
|---|
| 2 | OOO_CONFIG_NICE(config.nice) |
|---|
| 3 | MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION |
|---|
| 4 | AC_PREREQ(2.53) |
|---|
| 5 | AC_CONFIG_SRCDIR([src/mod_gnutls.c]) |
|---|
| 6 | AC_CONFIG_AUX_DIR(config) |
|---|
| 7 | |
|---|
| 8 | OOO_MAINTAIN_MODE |
|---|
| 9 | AM_MAINTAINER_MODE |
|---|
| 10 | AC_CANONICAL_TARGET |
|---|
| 11 | # mod_gnutls test suite requires GNU make |
|---|
| 12 | AM_INIT_AUTOMAKE([-Wno-portability]) |
|---|
| 13 | AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in) |
|---|
| 14 | |
|---|
| 15 | LT_INIT([disable-static]) |
|---|
| 16 | |
|---|
| 17 | AC_SUBST(MOD_GNUTLS_VERSION) |
|---|
| 18 | |
|---|
| 19 | AC_PROG_CC |
|---|
| 20 | AC_PROG_CC_C99 |
|---|
| 21 | AC_PROG_LD |
|---|
| 22 | AC_PROG_INSTALL |
|---|
| 23 | AC_PROG_LIBTOOL |
|---|
| 24 | |
|---|
| 25 | AC_CONFIG_MACRO_DIR([m4]) |
|---|
| 26 | |
|---|
| 27 | AP_VERSION=2.4.17 |
|---|
| 28 | CHECK_APACHE(,$AP_VERSION, |
|---|
| 29 | :,:, |
|---|
| 30 | AC_MSG_ERROR([*** Apache version $AP_VERSION not found!]) |
|---|
| 31 | ) |
|---|
| 32 | |
|---|
| 33 | dnl Maybe use the binaries for tests, too? |
|---|
| 34 | AC_ARG_WITH([gnutls-dev], |
|---|
| 35 | AS_HELP_STRING([--with-gnutls-dev=DIR], |
|---|
| 36 | [Use GnuTLS libraries from a development (git) tree. Use \ |
|---|
| 37 | this if you want to test mod_gnutls with the latest \ |
|---|
| 38 | GnuTLS code.]), |
|---|
| 39 | [ |
|---|
| 40 | AS_IF([test -d "${with_gnutls_dev}" ], |
|---|
| 41 | [ |
|---|
| 42 | LIBGNUTLS_CFLAGS="-I${with_gnutls_dev}/lib/includes" |
|---|
| 43 | LIBGNUTLS_LIBS="-lgnutls -L${with_gnutls_dev}/lib/.libs -R${with_gnutls_dev}/lib/.libs" |
|---|
| 44 | ], |
|---|
| 45 | [AC_MSG_ERROR([--with-gnutls-dev=DIR requires a directory!])]) |
|---|
| 46 | ], []) |
|---|
| 47 | |
|---|
| 48 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.3.0]) |
|---|
| 49 | |
|---|
| 50 | LIBGNUTLS_VERSION=`pkg-config --modversion gnutls` |
|---|
| 51 | |
|---|
| 52 | AC_ARG_ENABLE(vpath-install, |
|---|
| 53 | AS_HELP_STRING([--enable-vpath-install], |
|---|
| 54 | [Modify the Apache module directory provided by apxs to \ |
|---|
| 55 | follow --prefix, if necessary. Most users will not want this, \ |
|---|
| 56 | but it is required for VPATH builds including "make \ |
|---|
| 57 | distcheck".]), |
|---|
| 58 | vpath_install=$enableval, vpath_install=no) |
|---|
| 59 | AM_CONDITIONAL([ENABLE_VPATH_INSTALL], [test "$vpath_install" = "yes"]) |
|---|
| 60 | |
|---|
| 61 | AC_ARG_ENABLE(srp, |
|---|
| 62 | AS_HELP_STRING([--disable-srp], |
|---|
| 63 | [unconditionally disable the SRP functionality]), |
|---|
| 64 | use_srp=$enableval, use_srp=yes) |
|---|
| 65 | |
|---|
| 66 | # check if the available GnuTLS library supports SRP |
|---|
| 67 | AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"]) |
|---|
| 68 | |
|---|
| 69 | GNUTLS_FEAT_CFLAGS="" |
|---|
| 70 | if test "$use_srp" != "no"; then |
|---|
| 71 | GNUTLS_FEAT_CFLAGS="-DENABLE_SRP=1" |
|---|
| 72 | fi |
|---|
| 73 | |
|---|
| 74 | # check if the available GnuTLS library supports raw extension parsing |
|---|
| 75 | AC_SEARCH_LIBS([gnutls_ext_raw_parse], [gnutls], [early_sni="yes"], |
|---|
| 76 | [early_sni="no"]) |
|---|
| 77 | if test "$early_sni" != "no"; then |
|---|
| 78 | ENABLE_EARLY_SNI=1 |
|---|
| 79 | # This is for the test server configuration |
|---|
| 80 | EXPECT_EARLY_SNI="Define EXPECT_EARLY_SNI" |
|---|
| 81 | else |
|---|
| 82 | ENABLE_EARLY_SNI=0 |
|---|
| 83 | EXPECT_EARLY_SNI="" |
|---|
| 84 | fi |
|---|
| 85 | AC_SUBST(ENABLE_EARLY_SNI) |
|---|
| 86 | AC_SUBST(EXPECT_EARLY_SNI) |
|---|
| 87 | AM_SUBST_NOTMAKE(EXPECT_EARLY_SNI) |
|---|
| 88 | |
|---|
| 89 | AC_ARG_ENABLE(strict, |
|---|
| 90 | AS_HELP_STRING([--disable-strict], |
|---|
| 91 | [Avoid strict compiler warnings and errors]), |
|---|
| 92 | use_strict=$enableval, use_strict=yes) |
|---|
| 93 | |
|---|
| 94 | STRICT_CFLAGS="" |
|---|
| 95 | if test "$use_strict" != "no"; then |
|---|
| 96 | STRICT_CFLAGS="-Wall -Werror -Wextra -Wno-error=deprecated-declarations" |
|---|
| 97 | fi |
|---|
| 98 | |
|---|
| 99 | AC_MSG_CHECKING([whether to enable SRP functionality]) |
|---|
| 100 | AC_MSG_RESULT($use_srp) |
|---|
| 101 | |
|---|
| 102 | dnl Optionally disable flock |
|---|
| 103 | AC_ARG_ENABLE(flock, |
|---|
| 104 | AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \ |
|---|
| 105 | (some exotic architectures don't support it)]), |
|---|
| 106 | [use_flock=$enableval], [use_flock=yes]) |
|---|
| 107 | # Check if flock is available and supports --timeout |
|---|
| 108 | AC_PATH_PROG([FLOCK], [flock], [no]) |
|---|
| 109 | AS_IF([test "${FLOCK}" != "no"], |
|---|
| 110 | [ |
|---|
| 111 | AC_MSG_CHECKING([whether ${FLOCK} supports --timeout]) |
|---|
| 112 | lockfile="$(mktemp)" |
|---|
| 113 | AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1], |
|---|
| 114 | [flock_works="yes"], [flock_works="no"]) |
|---|
| 115 | AC_MSG_RESULT([$flock_works]) |
|---|
| 116 | # Old versions of flock do not support --verbose. They fail |
|---|
| 117 | # without executing the command but still return 0. Check for |
|---|
| 118 | # this behavior by testing if the rm command was executed. |
|---|
| 119 | AC_MSG_CHECKING([whether ${FLOCK} supports --verbose]) |
|---|
| 120 | testfile="$(mktemp)" |
|---|
| 121 | AS_IF([${FLOCK} --verbose --timeout 1 ${lockfile} rm "${testfile}" \ |
|---|
| 122 | >&AS_MESSAGE_LOG_FD 2>&1; test ! -e "${testfile}"], |
|---|
| 123 | [flock_verbose="yes"; FLOCK="${FLOCK} --verbose"], |
|---|
| 124 | [flock_verbose="no"; rm "${testfile}"]) |
|---|
| 125 | AC_MSG_RESULT([$flock_verbose]) |
|---|
| 126 | rm "${lockfile}" |
|---|
| 127 | ], |
|---|
| 128 | [flock_works="no"]) |
|---|
| 129 | # disable flock if requested by user or it doesn't support timeout |
|---|
| 130 | AM_CONDITIONAL([DISABLE_FLOCK], |
|---|
| 131 | [test "$enable_flock" = "no" || test "$flock_works" = "no"]) |
|---|
| 132 | |
|---|
| 133 | # openssl is needed as the responder for OCSP tests |
|---|
| 134 | AC_PATH_PROG([OPENSSL], [openssl], [no]) |
|---|
| 135 | # OCSP checks with gnutls-cli from GnuTLS versions before 3.3.23, |
|---|
| 136 | # 3.4.12, or 3.5.1 (on the respective 3.x branch) fail if intermediate |
|---|
| 137 | # CAs cannot be status checked, even if there are no intermediate CAs |
|---|
| 138 | # like in the mod_gnutls test suite where end entity certificates are |
|---|
| 139 | # directly issued by a root CA. |
|---|
| 140 | AC_MSG_CHECKING([for gnutls-cli version supporting OCSP for EE under root CA]) |
|---|
| 141 | AC_PREPROC_IFELSE( |
|---|
| 142 | [AC_LANG_SOURCE([[#include "gnutls/gnutls.h" |
|---|
| 143 | #if GNUTLS_VERSION_NUMBER < 0x030317 |
|---|
| 144 | #error |
|---|
| 145 | #elif GNUTLS_VERSION_NUMBER >= 0x030400 && GNUTLS_VERSION_NUMBER < 0x03040c |
|---|
| 146 | #error |
|---|
| 147 | #elif GNUTLS_VERSION_NUMBER == 0x030500 |
|---|
| 148 | #error |
|---|
| 149 | #endif |
|---|
| 150 | ]])], |
|---|
| 151 | [gnutls_ocsp_ok="yes"], |
|---|
| 152 | [gnutls_ocsp_ok="no"], |
|---|
| 153 | ) |
|---|
| 154 | AC_MSG_RESULT([$gnutls_ocsp_ok]) |
|---|
| 155 | AM_CONDITIONAL([ENABLE_OCSP_TEST], [test "${OPENSSL}" != "no" && test "${gnutls_ocsp_ok}" = "yes"]) |
|---|
| 156 | |
|---|
| 157 | dnl Enable test namespaces? Default is "yes". |
|---|
| 158 | AC_ARG_ENABLE(test-namespaces, |
|---|
| 159 | AS_HELP_STRING([--disable-test-namespaces], [Disable use of \ |
|---|
| 160 | namespaces for tests (limits parallelization)]), |
|---|
| 161 | [use_netns=$enableval], [use_netns=yes]) |
|---|
| 162 | |
|---|
| 163 | # Check if "unshare" is available and has permission to create |
|---|
| 164 | # network, IPC, and user namespaces |
|---|
| 165 | AC_PATH_PROG([UNSHARE], [unshare], [no]) |
|---|
| 166 | AS_IF([test "${UNSHARE}" != "no"], |
|---|
| 167 | [ |
|---|
| 168 | AC_MSG_CHECKING([for permission to use namespaces]) |
|---|
| 169 | AS_IF([${UNSHARE} --net --ipc -r /bin/sh -c \ |
|---|
| 170 | "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1], |
|---|
| 171 | [unshare_works="yes"], [unshare_works="no"]) |
|---|
| 172 | AC_MSG_RESULT([$unshare_works]) |
|---|
| 173 | ], |
|---|
| 174 | [unshare_works="no"]) |
|---|
| 175 | # decide whether to enable network namespaces |
|---|
| 176 | AS_IF([test "$enable_test_namespaces" != "no" \ |
|---|
| 177 | && test "$unshare_works" = "yes"], |
|---|
| 178 | [use_netns="yes"], [use_netns="no"]) |
|---|
| 179 | AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"]) |
|---|
| 180 | # Adjust Apache configuration for tests accordingly: Use pthread mutex |
|---|
| 181 | # and test specific PID files if using namespaces, defaults otherwise. |
|---|
| 182 | AS_IF([test "$use_netns" = "yes"], |
|---|
| 183 | [MUTEX_CONF="Mutex pthread default"; PID_AFFIX="-\${TEST_NAME}"], |
|---|
| 184 | [MUTEX_CONF=""; PID_AFFIX=""]) |
|---|
| 185 | AC_SUBST(MUTEX_CONF) |
|---|
| 186 | AC_SUBST(PID_AFFIX) |
|---|
| 187 | AM_SUBST_NOTMAKE(MUTEX_CONF) |
|---|
| 188 | AM_SUBST_NOTMAKE(PID_AFFIX) |
|---|
| 189 | |
|---|
| 190 | AC_ARG_ENABLE(msva, |
|---|
| 191 | AS_HELP_STRING([--enable-msva], |
|---|
| 192 | [enable Monkeysphere client certificate verification]), |
|---|
| 193 | use_msva=$enableval, use_msva=no) |
|---|
| 194 | AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"]) |
|---|
| 195 | |
|---|
| 196 | MSVA_CFLAGS="" |
|---|
| 197 | if test "$use_msva" != "no"; then |
|---|
| 198 | AC_CHECK_HEADERS([msv/msv.h], [], |
|---|
| 199 | [AC_MSG_ERROR([*** No libmsv headers found!])]) |
|---|
| 200 | AC_SEARCH_LIBS([msv_query_agent], [msv], [], |
|---|
| 201 | [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])]) |
|---|
| 202 | MSVA_CFLAGS="-DENABLE_MSVA=1" |
|---|
| 203 | fi |
|---|
| 204 | |
|---|
| 205 | AC_MSG_CHECKING([whether to enable MSVA functionality]) |
|---|
| 206 | AC_MSG_RESULT($use_msva) |
|---|
| 207 | |
|---|
| 208 | # Building documentation requires pandoc, which in turn needs pdflatex |
|---|
| 209 | # to build PDF output. |
|---|
| 210 | build_doc=no |
|---|
| 211 | AC_PATH_PROG([PANDOC], [pandoc], [no]) |
|---|
| 212 | if test "$PANDOC" != "no"; then |
|---|
| 213 | AC_PATH_PROG([PDFLATEX], [pdflatex], [no]) |
|---|
| 214 | if test "$PDFLATEX" != "no"; then |
|---|
| 215 | build_doc="html, manual page, pdf" |
|---|
| 216 | else |
|---|
| 217 | build_doc="html, manual page" |
|---|
| 218 | fi |
|---|
| 219 | else |
|---|
| 220 | AC_PATH_PROG([MARKDOWN], [markdown], [no]) |
|---|
| 221 | if test "$MARKDOWN" != "no"; then |
|---|
| 222 | build_doc="html stub" |
|---|
| 223 | fi |
|---|
| 224 | fi |
|---|
| 225 | AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"]) |
|---|
| 226 | AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \ |
|---|
| 227 | test "$PDFLATEX" != "no"]) |
|---|
| 228 | AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \ |
|---|
| 229 | test "$MARKDOWN" != "no"]) |
|---|
| 230 | |
|---|
| 231 | # Check for Apache binary |
|---|
| 232 | AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin]) |
|---|
| 233 | if test "${APACHE2}" = "no"; then |
|---|
| 234 | AC_MSG_WARN([Neither apache2 nor httpd found in \ |
|---|
| 235 | PATH. Test suite will fail.]) |
|---|
| 236 | fi |
|---|
| 237 | |
|---|
| 238 | AC_PATH_PROGS([HTTP_CLI], [curl wget], [no]) |
|---|
| 239 | |
|---|
| 240 | MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${GNUTLS_FEAT_CFLAGS} ${MSVA_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}" |
|---|
| 241 | MODULE_LIBS="${LIBGNUTLS_LIBS}" |
|---|
| 242 | |
|---|
| 243 | AC_PATH_PROGS([SOFTHSM], [softhsm2-util softhsm], [no]) |
|---|
| 244 | if test "${SOFTHSM}" != "no"; then |
|---|
| 245 | softhsm_version=$(${SOFTHSM} --version) |
|---|
| 246 | AS_VERSION_COMPARE([$(${SOFTHSM} --version)], [2.0.0], |
|---|
| 247 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [1])], |
|---|
| 248 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])], |
|---|
| 249 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])]) |
|---|
| 250 | fi |
|---|
| 251 | AM_CONDITIONAL([HAVE_SOFTHSM], [test "${SOFTHSM}" != "no"]) |
|---|
| 252 | AM_CONDITIONAL([HAVE_SOFTHSM1], [test "${SOFTHSM_MAJOR_VERSION}" = "1"]) |
|---|
| 253 | AM_CONDITIONAL([HAVE_SOFTHSM2], [test "${SOFTHSM_MAJOR_VERSION}" = "2"]) |
|---|
| 254 | |
|---|
| 255 | AC_SUBST(MODULE_CFLAGS) |
|---|
| 256 | AC_SUBST(MODULE_LIBS) |
|---|
| 257 | |
|---|
| 258 | # assign default values to TEST_HOST and TEST_IP if necessary |
|---|
| 259 | : ${TEST_HOST:="localhost"} |
|---|
| 260 | : ${TEST_IP:="[[::1]] 127.0.0.1"} |
|---|
| 261 | AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \ |
|---|
| 262 | "make check", must resolve to addresses in TEST_IP. \ |
|---|
| 263 | The default is "localhost".]) |
|---|
| 264 | AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \ |
|---|
| 265 | started by "make check". The default is \ |
|---|
| 266 | "[::1] 127.0.0.1". Note that IPv6 addresses must be \ |
|---|
| 267 | enclosed in square brackets.]) |
|---|
| 268 | |
|---|
| 269 | : ${TEST_LOCK_WAIT:="30"} |
|---|
| 270 | : ${TEST_QUERY_TIMEOUT:="30"} |
|---|
| 271 | AC_ARG_VAR([TEST_LOCK_WAIT], [Timeout in seconds to acquire locks for \ |
|---|
| 272 | Apache instances in the test suite, or the \ |
|---|
| 273 | previous instance to remove its PID file if \ |
|---|
| 274 | flock is not used. Default is 30.]) |
|---|
| 275 | AC_ARG_VAR([TEST_QUERY_TIMEOUT], [Timeout in seconds for HTTPS requests \ |
|---|
| 276 | sent using gnutls-cli in the test suite. \ |
|---|
| 277 | Default is 30.]) |
|---|
| 278 | |
|---|
| 279 | dnl Allow user to set SoftHSM PKCS #11 module |
|---|
| 280 | AC_ARG_VAR([SOFTHSM_LIB], [Absolute path of the SoftHSM PKCS @%:@11 module to \ |
|---|
| 281 | use. By default the test suite will search common \ |
|---|
| 282 | library paths.]) |
|---|
| 283 | |
|---|
| 284 | dnl Build list of "Listen" statements for Apache |
|---|
| 285 | LISTEN_LIST="@%:@ Listen addresses for the test servers" |
|---|
| 286 | for i in ${TEST_IP}; do |
|---|
| 287 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 288 | Listen ${i}:\${TEST_PORT}" |
|---|
| 289 | done |
|---|
| 290 | # Available extra ports, tests can "Define" variables of the listed |
|---|
| 291 | # names in their apache.conf to enable them. |
|---|
| 292 | for j in TEST_HTTP_PORT; do |
|---|
| 293 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 294 | <IfDefine ${j}>" |
|---|
| 295 | for i in ${TEST_IP}; do |
|---|
| 296 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 297 | Listen ${i}:\${${j}}" |
|---|
| 298 | done |
|---|
| 299 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 300 | </IfDefine>" |
|---|
| 301 | done |
|---|
| 302 | AC_SUBST(LISTEN_LIST) |
|---|
| 303 | AM_SUBST_NOTMAKE(LISTEN_LIST) |
|---|
| 304 | |
|---|
| 305 | DX_DOXYGEN_FEATURE(ON) |
|---|
| 306 | DX_DOT_FEATURE(ON) |
|---|
| 307 | DX_HTML_FEATURE(ON) |
|---|
| 308 | DX_MAN_FEATURE(OFF) |
|---|
| 309 | DX_RTF_FEATURE(OFF) |
|---|
| 310 | DX_XML_FEATURE(OFF) |
|---|
| 311 | DX_PDF_FEATURE(OFF) |
|---|
| 312 | DX_PS_FEATURE(OFF) |
|---|
| 313 | DX_INIT_DOXYGEN([mod_gnutls], [doc/doxygen.conf], [doc/api]) |
|---|
| 314 | |
|---|
| 315 | AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \ |
|---|
| 316 | doc/Makefile doc/doxygen.conf include/mod_gnutls.h \ |
|---|
| 317 | test/proxy_backend.conf test/ocsp_server.conf \ |
|---|
| 318 | test/apache-conf/early_sni.conf \ |
|---|
| 319 | test/apache-conf/listen.conf \ |
|---|
| 320 | test/apache-conf/netns.conf]) |
|---|
| 321 | AC_OUTPUT |
|---|
| 322 | |
|---|
| 323 | echo "---" |
|---|
| 324 | echo "Configuration summary for mod_gnutls:" |
|---|
| 325 | echo "" |
|---|
| 326 | echo " * mod_gnutls version: ${MOD_GNUTLS_VERSION}" |
|---|
| 327 | echo " * Apache Modules directory: ${AP_LIBEXECDIR}" |
|---|
| 328 | echo " * GnuTLS Library version: ${LIBGNUTLS_VERSION}" |
|---|
| 329 | echo " * CFLAGS for GnuTLS: ${LIBGNUTLS_CFLAGS}" |
|---|
| 330 | echo " * LDFLAGS for GnuTLS: ${LIBGNUTLS_LIBS}" |
|---|
| 331 | echo " * SRP Authentication: ${use_srp}" |
|---|
| 332 | echo " * MSVA Client Verification: ${use_msva}" |
|---|
| 333 | echo " * Early SNI: ${early_sni}" |
|---|
| 334 | echo " * Build documentation: ${build_doc}" |
|---|
| 335 | echo "" |
|---|
| 336 | echo "---" |
|---|
