| 1 | AC_INIT(mod_gnutls, 0.8.4) |
|---|
| 2 | OOO_CONFIG_NICE(config.nice) |
|---|
| 3 | MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION |
|---|
| 4 | AC_PREREQ(2.53) |
|---|
| 5 | AC_CONFIG_SRCDIR([src/mod_gnutls.c]) |
|---|
| 6 | AC_CONFIG_AUX_DIR(config) |
|---|
| 7 | |
|---|
| 8 | OOO_MAINTAIN_MODE |
|---|
| 9 | AM_MAINTAINER_MODE |
|---|
| 10 | AC_CANONICAL_TARGET |
|---|
| 11 | # mod_gnutls test suite requires GNU make |
|---|
| 12 | AM_INIT_AUTOMAKE([-Wno-portability]) |
|---|
| 13 | AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in) |
|---|
| 14 | |
|---|
| 15 | LT_INIT([disable-static]) |
|---|
| 16 | |
|---|
| 17 | AC_SUBST(MOD_GNUTLS_VERSION) |
|---|
| 18 | |
|---|
| 19 | AC_PROG_CC |
|---|
| 20 | AC_PROG_CC_C99 |
|---|
| 21 | AC_PROG_LD |
|---|
| 22 | AC_PROG_INSTALL |
|---|
| 23 | AC_PROG_LIBTOOL |
|---|
| 24 | |
|---|
| 25 | AC_CONFIG_MACRO_DIR([m4]) |
|---|
| 26 | |
|---|
| 27 | AP_VERSION=2.4.17 |
|---|
| 28 | CHECK_APACHE(,$AP_VERSION, |
|---|
| 29 | :,:, |
|---|
| 30 | AC_MSG_ERROR([*** Apache version $AP_VERSION not found!]) |
|---|
| 31 | ) |
|---|
| 32 | |
|---|
| 33 | PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.3.0]) |
|---|
| 34 | |
|---|
| 35 | LIBGNUTLS_VERSION=`pkg-config --modversion gnutls` |
|---|
| 36 | |
|---|
| 37 | AC_ARG_ENABLE(vpath-install, |
|---|
| 38 | AS_HELP_STRING([--enable-vpath-install], |
|---|
| 39 | [Modify the Apache module directory provided by apxs to \ |
|---|
| 40 | follow --prefix, if necessary. Most users will not want this, \ |
|---|
| 41 | but it is required for VPATH builds including "make \ |
|---|
| 42 | distcheck".]), |
|---|
| 43 | vpath_install=$enableval, vpath_install=no) |
|---|
| 44 | AM_CONDITIONAL([ENABLE_VPATH_INSTALL], [test "$vpath_install" = "yes"]) |
|---|
| 45 | |
|---|
| 46 | AC_ARG_ENABLE(srp, |
|---|
| 47 | AS_HELP_STRING([--disable-srp], |
|---|
| 48 | [unconditionally disable the SRP functionality]), |
|---|
| 49 | use_srp=$enableval, use_srp=yes) |
|---|
| 50 | |
|---|
| 51 | # check if the available GnuTLS library supports SRP |
|---|
| 52 | AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"]) |
|---|
| 53 | |
|---|
| 54 | SRP_CFLAGS="" |
|---|
| 55 | if test "$use_srp" != "no"; then |
|---|
| 56 | SRP_CFLAGS="-DENABLE_SRP=1" |
|---|
| 57 | fi |
|---|
| 58 | |
|---|
| 59 | AC_ARG_ENABLE(strict, |
|---|
| 60 | AS_HELP_STRING([--disable-strict], |
|---|
| 61 | [Avoid strict compiler warnings and errors]), |
|---|
| 62 | use_strict=$enableval, use_strict=yes) |
|---|
| 63 | |
|---|
| 64 | STRICT_CFLAGS="" |
|---|
| 65 | if test "$use_strict" != "no"; then |
|---|
| 66 | STRICT_CFLAGS="-Wall -Werror -Wextra -Wno-error=deprecated-declarations" |
|---|
| 67 | fi |
|---|
| 68 | |
|---|
| 69 | AC_MSG_CHECKING([whether to enable SRP functionality]) |
|---|
| 70 | AC_MSG_RESULT($use_srp) |
|---|
| 71 | |
|---|
| 72 | dnl Optionally disable flock |
|---|
| 73 | AC_ARG_ENABLE(flock, |
|---|
| 74 | AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \ |
|---|
| 75 | (some exotic architectures don't support it)]), |
|---|
| 76 | [use_flock=$enableval], [use_flock=yes]) |
|---|
| 77 | # Check if flock is available and supports --timeout |
|---|
| 78 | AC_PATH_PROG([FLOCK], [flock], [no]) |
|---|
| 79 | AS_IF([test "${FLOCK}" != "no"], |
|---|
| 80 | [ |
|---|
| 81 | AC_MSG_CHECKING([whether ${FLOCK} supports --timeout]) |
|---|
| 82 | lockfile="$(mktemp)" |
|---|
| 83 | AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1], |
|---|
| 84 | [flock_works="yes"], [flock_works="no"]) |
|---|
| 85 | AC_MSG_RESULT([$flock_works]) |
|---|
| 86 | # Old versions of flock do not support --verbose. They fail |
|---|
| 87 | # without executing the command but still return 0. Check for |
|---|
| 88 | # this behavior by testing if the rm command was executed. |
|---|
| 89 | AC_MSG_CHECKING([whether ${FLOCK} supports --verbose]) |
|---|
| 90 | testfile="$(mktemp)" |
|---|
| 91 | AS_IF([${FLOCK} --verbose --timeout 1 ${lockfile} rm "${testfile}" \ |
|---|
| 92 | >&AS_MESSAGE_LOG_FD 2>&1; test ! -e "${testfile}"], |
|---|
| 93 | [flock_verbose="yes"; FLOCK="${FLOCK} --verbose"], |
|---|
| 94 | [flock_verbose="no"; rm "${testfile}"]) |
|---|
| 95 | AC_MSG_RESULT([$flock_verbose]) |
|---|
| 96 | rm "${lockfile}" |
|---|
| 97 | ], |
|---|
| 98 | [flock_works="no"]) |
|---|
| 99 | # disable flock if requested by user or it doesn't support timeout |
|---|
| 100 | AM_CONDITIONAL([DISABLE_FLOCK], |
|---|
| 101 | [test "$enable_flock" = "no" || test "$flock_works" = "no"]) |
|---|
| 102 | |
|---|
| 103 | # openssl is needed as the responder for OCSP tests |
|---|
| 104 | AC_PATH_PROG([OPENSSL], [openssl], [no]) |
|---|
| 105 | # OCSP checks with gnutls-cli from GnuTLS versions before 3.3.23, |
|---|
| 106 | # 3.4.12, or 3.5.1 (on the respective 3.x branch) fail if intermediate |
|---|
| 107 | # CAs cannot be status checked, even if there are no intermediate CAs |
|---|
| 108 | # like in the mod_gnutls test suite where end entity certificates are |
|---|
| 109 | # directly issued by a root CA. |
|---|
| 110 | AC_MSG_CHECKING([for gnutls-cli version supporting OCSP for EE under root CA]) |
|---|
| 111 | AC_PREPROC_IFELSE( |
|---|
| 112 | [AC_LANG_SOURCE([[#include "gnutls/gnutls.h" |
|---|
| 113 | #if GNUTLS_VERSION_NUMBER < 0x030317 |
|---|
| 114 | #error |
|---|
| 115 | #elif GNUTLS_VERSION_NUMBER >= 0x030400 && GNUTLS_VERSION_NUMBER < 0x03040c |
|---|
| 116 | #error |
|---|
| 117 | #elif GNUTLS_VERSION_NUMBER == 0x030500 |
|---|
| 118 | #error |
|---|
| 119 | #endif |
|---|
| 120 | ]])], |
|---|
| 121 | [gnutls_ocsp_ok="yes"], |
|---|
| 122 | [gnutls_ocsp_ok="no"], |
|---|
| 123 | ) |
|---|
| 124 | AC_MSG_RESULT([$gnutls_ocsp_ok]) |
|---|
| 125 | AM_CONDITIONAL([ENABLE_OCSP_TEST], [test "${OPENSSL}" != "no" && test "${gnutls_ocsp_ok}" = "yes"]) |
|---|
| 126 | |
|---|
| 127 | dnl Enable test namespaces? Default is "yes". |
|---|
| 128 | AC_ARG_ENABLE(test-namespaces, |
|---|
| 129 | AS_HELP_STRING([--disable-test-namespaces], [Disable use of network \ |
|---|
| 130 | namespaces to run tests in parallel (some architectures might not \ |
|---|
| 131 | support it)]), |
|---|
| 132 | [use_netns=$enableval], [use_netns=yes]) |
|---|
| 133 | |
|---|
| 134 | # Check if "unshare" is available and has permission to create network |
|---|
| 135 | # and user namespaces |
|---|
| 136 | AC_PATH_PROG([UNSHARE], [unshare], [no]) |
|---|
| 137 | AS_IF([test "${UNSHARE}" != "no"], |
|---|
| 138 | [ |
|---|
| 139 | AC_MSG_CHECKING([for permission to create network and user namespaces]) |
|---|
| 140 | AS_IF([${UNSHARE} --net -r /bin/sh -c \ |
|---|
| 141 | "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1], |
|---|
| 142 | [unshare_works="yes"], [unshare_works="no"]) |
|---|
| 143 | AC_MSG_RESULT([$unshare_works]) |
|---|
| 144 | ], |
|---|
| 145 | [unshare_works="no"]) |
|---|
| 146 | # decide whether to enable network namespaces |
|---|
| 147 | AS_IF([test "$enable_test_namespaces" != "no" \ |
|---|
| 148 | && test "$unshare_works" = "yes"], |
|---|
| 149 | [use_netns="yes"], [use_netns="no"]) |
|---|
| 150 | AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"]) |
|---|
| 151 | # Adjust Apache configuration for tests accordingly: Use pthread mutex |
|---|
| 152 | # and test specific PID files if using namespaces, defaults otherwise. |
|---|
| 153 | AS_IF([test "$use_netns" = "yes"], |
|---|
| 154 | [MUTEX_CONF="Mutex pthread default"; PID_AFFIX="-\${TEST_NAME}"], |
|---|
| 155 | [MUTEX_CONF=""; PID_AFFIX=""]) |
|---|
| 156 | AC_SUBST(MUTEX_CONF) |
|---|
| 157 | AC_SUBST(PID_AFFIX) |
|---|
| 158 | AM_SUBST_NOTMAKE(MUTEX_CONF) |
|---|
| 159 | AM_SUBST_NOTMAKE(PID_AFFIX) |
|---|
| 160 | |
|---|
| 161 | AC_ARG_ENABLE(msva, |
|---|
| 162 | AS_HELP_STRING([--enable-msva], |
|---|
| 163 | [enable Monkeysphere client certificate verification]), |
|---|
| 164 | use_msva=$enableval, use_msva=no) |
|---|
| 165 | AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"]) |
|---|
| 166 | |
|---|
| 167 | MSVA_CFLAGS="" |
|---|
| 168 | if test "$use_msva" != "no"; then |
|---|
| 169 | AC_CHECK_HEADERS([msv/msv.h], [], |
|---|
| 170 | [AC_MSG_ERROR([*** No libmsv headers found!])]) |
|---|
| 171 | AC_SEARCH_LIBS([msv_query_agent], [msv], [], |
|---|
| 172 | [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])]) |
|---|
| 173 | MSVA_CFLAGS="-DENABLE_MSVA=1" |
|---|
| 174 | fi |
|---|
| 175 | |
|---|
| 176 | AC_MSG_CHECKING([whether to enable MSVA functionality]) |
|---|
| 177 | AC_MSG_RESULT($use_msva) |
|---|
| 178 | |
|---|
| 179 | # Building documentation requires pandoc, which in turn needs pdflatex |
|---|
| 180 | # to build PDF output. |
|---|
| 181 | build_doc=no |
|---|
| 182 | AC_PATH_PROG([PANDOC], [pandoc], [no]) |
|---|
| 183 | if test "$PANDOC" != "no"; then |
|---|
| 184 | AC_PATH_PROG([PDFLATEX], [pdflatex], [no]) |
|---|
| 185 | if test "$PDFLATEX" != "no"; then |
|---|
| 186 | build_doc=yes |
|---|
| 187 | else |
|---|
| 188 | build_doc="html only" |
|---|
| 189 | fi |
|---|
| 190 | else |
|---|
| 191 | AC_PATH_PROG([MARKDOWN], [markdown], [no]) |
|---|
| 192 | if test "$MARKDOWN" != "no"; then |
|---|
| 193 | build_doc="html stub" |
|---|
| 194 | fi |
|---|
| 195 | fi |
|---|
| 196 | AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"]) |
|---|
| 197 | AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \ |
|---|
| 198 | test "$PDFLATEX" != "no"]) |
|---|
| 199 | AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \ |
|---|
| 200 | test "$MARKDOWN" != "no"]) |
|---|
| 201 | |
|---|
| 202 | # Check for Apache binary |
|---|
| 203 | AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin]) |
|---|
| 204 | if test "${APACHE2}" = "no"; then |
|---|
| 205 | AC_MSG_WARN([Neither apache2 nor httpd found in \ |
|---|
| 206 | PATH. Test suite will fail.]) |
|---|
| 207 | fi |
|---|
| 208 | |
|---|
| 209 | AC_PATH_PROGS([HTTP_CLI], [curl wget], [no]) |
|---|
| 210 | |
|---|
| 211 | MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${SRP_CFLAGS} ${MSVA_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}" |
|---|
| 212 | MODULE_LIBS="${LIBGNUTLS_LIBS}" |
|---|
| 213 | |
|---|
| 214 | AC_PATH_PROGS([SOFTHSM], [softhsm2-util softhsm], [no]) |
|---|
| 215 | if test "${SOFTHSM}" != "no"; then |
|---|
| 216 | softhsm_version=$(${SOFTHSM} --version) |
|---|
| 217 | AS_VERSION_COMPARE([$(${SOFTHSM} --version)], [2.0.0], |
|---|
| 218 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [1])], |
|---|
| 219 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])], |
|---|
| 220 | [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])]) |
|---|
| 221 | fi |
|---|
| 222 | AM_CONDITIONAL([HAVE_SOFTHSM], [test "${SOFTHSM}" != "no"]) |
|---|
| 223 | AM_CONDITIONAL([HAVE_SOFTHSM1], [test "${SOFTHSM_MAJOR_VERSION}" = "1"]) |
|---|
| 224 | AM_CONDITIONAL([HAVE_SOFTHSM2], [test "${SOFTHSM_MAJOR_VERSION}" = "2"]) |
|---|
| 225 | |
|---|
| 226 | AC_SUBST(MODULE_CFLAGS) |
|---|
| 227 | AC_SUBST(MODULE_LIBS) |
|---|
| 228 | |
|---|
| 229 | # assign default values to TEST_HOST and TEST_IP if necessary |
|---|
| 230 | : ${TEST_HOST:="localhost"} |
|---|
| 231 | : ${TEST_IP:="[[::1]] 127.0.0.1"} |
|---|
| 232 | AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \ |
|---|
| 233 | "make check", must resolve to addresses in TEST_IP. \ |
|---|
| 234 | The default is "localhost".]) |
|---|
| 235 | AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \ |
|---|
| 236 | started by "make check". The default is \ |
|---|
| 237 | "[::1] 127.0.0.1". Note that IPv6 addresses must be \ |
|---|
| 238 | enclosed in square brackets.]) |
|---|
| 239 | AM_SUBST_NOTMAKE(TEST_IP) |
|---|
| 240 | |
|---|
| 241 | : ${TEST_LOCK_WAIT:="30"} |
|---|
| 242 | : ${TEST_QUERY_TIMEOUT:="30"} |
|---|
| 243 | AC_ARG_VAR([TEST_LOCK_WAIT], [Timeout in seconds to acquire locks for \ |
|---|
| 244 | Apache instances in the test suite, or the \ |
|---|
| 245 | previous instance to remove its PID file if \ |
|---|
| 246 | flock is not used. Default is 30.]) |
|---|
| 247 | AC_ARG_VAR([TEST_QUERY_TIMEOUT], [Timeout in seconds for HTTPS requests \ |
|---|
| 248 | sent using gnutls-cli in the test suite. \ |
|---|
| 249 | Default is 30.]) |
|---|
| 250 | |
|---|
| 251 | dnl Allow user to set SoftHSM PKCS #11 module |
|---|
| 252 | AC_ARG_VAR([SOFTHSM_LIB], [Absolute path of the SoftHSM PKCS @%:@11 module to \ |
|---|
| 253 | use. By default the test suite will search common \ |
|---|
| 254 | library paths.]) |
|---|
| 255 | |
|---|
| 256 | dnl Build list of "Listen" statements for Apache |
|---|
| 257 | LISTEN_LIST="@%:@ Listen addresses for the test servers" |
|---|
| 258 | for i in ${TEST_IP}; do |
|---|
| 259 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 260 | Listen ${i}:\${TEST_PORT}" |
|---|
| 261 | done |
|---|
| 262 | # Available extra ports, tests can "Define" variables of the listed |
|---|
| 263 | # names in their apache.conf to enable them. |
|---|
| 264 | for j in TEST_HTTP_PORT; do |
|---|
| 265 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 266 | <IfDefine ${j}>" |
|---|
| 267 | for i in ${TEST_IP}; do |
|---|
| 268 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 269 | Listen ${i}:\${${j}}" |
|---|
| 270 | done |
|---|
| 271 | LISTEN_LIST="${LISTEN_LIST} |
|---|
| 272 | </IfDefine>" |
|---|
| 273 | done |
|---|
| 274 | AC_SUBST(LISTEN_LIST) |
|---|
| 275 | AM_SUBST_NOTMAKE(LISTEN_LIST) |
|---|
| 276 | |
|---|
| 277 | DX_DOXYGEN_FEATURE(ON) |
|---|
| 278 | DX_DOT_FEATURE(ON) |
|---|
| 279 | DX_HTML_FEATURE(ON) |
|---|
| 280 | DX_MAN_FEATURE(OFF) |
|---|
| 281 | DX_RTF_FEATURE(OFF) |
|---|
| 282 | DX_XML_FEATURE(OFF) |
|---|
| 283 | DX_PDF_FEATURE(ON) |
|---|
| 284 | DX_PS_FEATURE(OFF) |
|---|
| 285 | DX_INIT_DOXYGEN([mod_gnutls], [doc/doxygen.conf], [doc/api]) |
|---|
| 286 | |
|---|
| 287 | AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \ |
|---|
| 288 | doc/Makefile doc/doxygen.conf include/mod_gnutls.h \ |
|---|
| 289 | test/proxy_backend.conf test/ocsp_server.conf \ |
|---|
| 290 | test/apache-conf/listen.conf \ |
|---|
| 291 | test/apache-conf/netns.conf]) |
|---|
| 292 | AC_OUTPUT |
|---|
| 293 | |
|---|
| 294 | echo "---" |
|---|
| 295 | echo "Configuration summary for mod_gnutls:" |
|---|
| 296 | echo "" |
|---|
| 297 | echo " * mod_gnutls version: ${MOD_GNUTLS_VERSION}" |
|---|
| 298 | echo " * Apache Modules directory: ${AP_LIBEXECDIR}" |
|---|
| 299 | echo " * GnuTLS Library version: ${LIBGNUTLS_VERSION}" |
|---|
| 300 | echo " * CFLAGS for GnuTLS: ${LIBGNUTLS_CFLAGS}" |
|---|
| 301 | echo " * LDFLAGS for GnuTLS: ${LIBGNUTLS_LIBS}" |
|---|
| 302 | echo " * SRP Authentication: ${use_srp}" |
|---|
| 303 | echo " * MSVA Client Verification: ${use_msva}" |
|---|
| 304 | echo " * Build documentation: ${build_doc}" |
|---|
| 305 | echo "" |
|---|
| 306 | echo "---" |
|---|
