source: mod_gnutls/configure.ac @ dff57b4

debian/masterdebian/stretch-backportsjessie-backportsupstream
Last change on this file since dff57b4 was dff57b4, checked in by Thomas Klute <thomas2.klute@…>, 4 years ago

Update documentation for TEST_IP and "--disable-flock"

  • Property mode set to 100644
File size: 5.0 KB
Line 
1dnl
2AC_INIT(mod_gnutls, 0.7.2)
3OOO_CONFIG_NICE(config.nice)
4MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION
5AC_PREREQ(2.53)
6AC_CONFIG_SRCDIR([src/mod_gnutls.c])
7AC_CONFIG_AUX_DIR(config)
8
9OOO_MAINTAIN_MODE
10AM_MAINTAINER_MODE
11AC_CANONICAL_TARGET
12# mod_gnutls test suite requires GNU make
13AM_INIT_AUTOMAKE([-Wno-portability])
14AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in)
15
16AC_SUBST(MOD_GNUTLS_VERSION)
17
18AC_PROG_CC
19AC_PROG_CC_C99
20AC_PROG_LD
21AC_PROG_INSTALL
22AC_PROG_LIBTOOL
23
24AC_CONFIG_MACRO_DIR([m4])
25
26AP_VERSION=2.2.0
27CHECK_APACHE(,$AP_VERSION,
28    :,:,
29    AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
30)
31
32PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.4])
33
34LIBGNUTLS_VERSION=`pkg-config --modversion gnutls`
35
36AC_ARG_ENABLE(srp,
37       AS_HELP_STRING([--disable-srp],
38               [unconditionally disable the SRP functionality]),
39       use_srp=$enableval, use_srp=yes)
40
41# check if the available GnuTLS library supports SRP
42AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"])
43
44SRP_CFLAGS=""
45if test "$use_srp" != "no"; then
46        SRP_CFLAGS="-DENABLE_SRP=1"
47fi
48
49AC_ARG_ENABLE(strict,
50       AS_HELP_STRING([--disable-strict],
51               [Avoid strict compiler warnings and errors]),
52       use_strict=$enableval, use_strict=yes)
53
54STRICT_CFLAGS=""
55if test "$use_strict" != "no"; then
56        STRICT_CFLAGS="-Wall -Werror -Wextra"
57fi
58
59AC_MSG_CHECKING([whether to enable SRP functionality])
60AC_MSG_RESULT($use_srp)
61
62dnl Optionally disable flock
63AC_ARG_ENABLE(flock,
64        AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \
65        (some exotic architectures don't support it)]),
66        [use_flock=$enableval], [use_flock=yes])
67dnl If flock is not disabled, make sure it's available
68if test "$enable_flock" != "no"; then
69        AC_PATH_PROG([FLOCK], [flock], [no])
70        use_flock=${FLOCK}
71fi
72AM_CONDITIONAL([DISABLE_FLOCK], [test "$enable_flock" = "no"])
73
74AC_ARG_ENABLE(msva,
75       AS_HELP_STRING([--enable-msva],
76               [enable Monkeysphere client certificate verification]),
77       use_msva=$enableval, use_msva=no)
78AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"])
79
80MSVA_CFLAGS=""
81if test "$use_msva" != "no"; then
82        AC_CHECK_HEADERS([msv/msv.h], [],
83                         [AC_MSG_ERROR([*** No libmsv headers found!])])
84        AC_SEARCH_LIBS([msv_query_agent], [msv], [],
85                         [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])])
86        MSVA_CFLAGS="-DENABLE_MSVA=1"
87fi
88
89AC_MSG_CHECKING([whether to enable MSVA functionality])
90AC_MSG_RESULT($use_msva)
91
92have_apr_memcache=0
93CHECK_APR_MEMCACHE([have_apr_memcache=1], [have_apr_memcache=0])
94AC_SUBST(have_apr_memcache)
95
96# Building documentation requires pandoc, which in turn needs pdflatex
97# to build PDF output.
98build_doc=no
99AC_PATH_PROG([PANDOC], [pandoc], [no])
100if test "$PANDOC" != "no"; then
101        AC_PATH_PROG([PDFLATEX], [pdflatex], [no])
102        if test "$PDFLATEX" != "no"; then
103                build_doc=yes
104        else
105                build_doc="html only"
106        fi
107else
108        AC_PATH_PROG([MARKDOWN], [markdown], [no])
109        if test "$MARKDOWN" != "no"; then
110                build_doc="html stub"
111        fi
112fi
113AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"])
114AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \
115                               test "$PDFLATEX" != "no"])
116AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \
117                               test "$MARKDOWN" != "no"])
118
119# Check for Apache binary
120AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin])
121if test "${APACHE2}" = "no"; then
122        AC_MSG_WARN([Neither apache2 nor httpd found in \
123                     PATH. Test suite will fail.])
124fi
125
126MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${SRP_CFLAGS} ${MSVA_CFLAGS} ${APR_MEMCACHE_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}"
127MODULE_LIBS="${APR_MEMCACHE_LIBS} ${LIBGNUTLS_LIBS}"
128
129AC_SUBST(MODULE_CFLAGS)
130AC_SUBST(MODULE_LIBS)
131
132# assign default values to TEST_HOST and TEST_IP if necessary
133: ${TEST_HOST:="localhost"}
134: ${TEST_IP:="[[::1]] 127.0.0.1"}
135AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \
136                        "make check", must resolve to addresses in TEST_IP. \
137                        The default is "localhost".])
138AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \
139                      started by "make check". The default is \
140                      "[::1] 127.0.0.1". Note that IPv6 addresses must be \
141                      enclosed in square brackets.])
142AM_SUBST_NOTMAKE(TEST_IP)
143
144dnl Build list of "Listen" statements for Apache
145LISTEN_LIST="# Listen addresses for the test servers"
146for i in ${TEST_IP}; do
147        LISTEN_LIST="${LISTEN_LIST}
148Listen ${i}:\${TEST_PORT}"
149done
150AC_SUBST(LISTEN_LIST)
151AM_SUBST_NOTMAKE(LISTEN_LIST)
152
153AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \
154                          doc/Makefile include/mod_gnutls.h test/listen.conf])
155AC_OUTPUT
156
157echo "---"
158echo "Configuration summary for mod_gnutls:"
159echo ""
160echo "   * mod_gnutls version:  ${MOD_GNUTLS_VERSION}"
161echo "   * Apache Modules directory:    ${AP_LIBEXECDIR}"
162echo "   * GnuTLS Library version:      ${LIBGNUTLS_VERSION}"
163echo "   * SRP Authentication:  ${use_srp}"
164echo "   * MSVA Client Verification:    ${use_msva}"
165echo "   * Build documentation: ${build_doc}"
166echo ""
167echo "---"
Note: See TracBrowser for help on using the repository browser.