source: mod_gnutls/configure.ac @ e376ed8

proxy-ticket
Last change on this file since e376ed8 was e376ed8, checked in by Fiona Klute <fiona.klute@…>, 12 months ago

Merge branch 'subca'

  • Property mode set to 100644
File size: 10.6 KB
Line 
1AC_INIT(mod_gnutls, 0.9.1)
2OOO_CONFIG_NICE(config.nice)
3MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION
4AC_PREREQ(2.53)
5AC_CONFIG_SRCDIR([src/mod_gnutls.c])
6AC_CONFIG_AUX_DIR(config)
7
8OOO_MAINTAIN_MODE
9AM_MAINTAINER_MODE
10AC_CANONICAL_TARGET
11# mod_gnutls test suite requires GNU make
12AM_INIT_AUTOMAKE([-Wno-portability])
13AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in)
14
15LT_INIT([disable-static])
16
17AC_SUBST(MOD_GNUTLS_VERSION)
18
19AC_PROG_CC
20AC_PROG_CC_C99
21AC_PROG_LD
22AC_PROG_INSTALL
23AC_PROG_LIBTOOL
24
25AC_CONFIG_MACRO_DIR([m4])
26
27AP_VERSION=2.4.17
28CHECK_APACHE(,$AP_VERSION,
29    :,:,
30    AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
31)
32
33dnl Maybe use the binaries for tests, too?
34AC_ARG_WITH([gnutls-dev],
35        AS_HELP_STRING([--with-gnutls-dev=DIR],
36                [Use GnuTLS libraries from a development (git) tree. Use \
37                this if you want to test mod_gnutls with the latest \
38                GnuTLS code.]),
39        [
40                AS_IF([test -d "${with_gnutls_dev}" ],
41                [
42                        LIBGNUTLS_CFLAGS="-I${with_gnutls_dev}/lib/includes"
43                        LIBGNUTLS_LIBS="-lgnutls -L${with_gnutls_dev}/lib/.libs -R${with_gnutls_dev}/lib/.libs"
44                ],
45                [AC_MSG_ERROR([--with-gnutls-dev=DIR requires a directory!])])
46        ], [])
47
48PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.6.3])
49
50LIBGNUTLS_VERSION=`pkg-config --modversion gnutls`
51
52AC_ARG_ENABLE(vpath-install,
53       AS_HELP_STRING([--enable-vpath-install],
54               [Modify the Apache module directory provided by apxs to \
55               follow --prefix, if necessary. Most users will not want this, \
56               but it is required for VPATH builds including "make \
57               distcheck".]),
58       vpath_install=$enableval, vpath_install=no)
59AM_CONDITIONAL([ENABLE_VPATH_INSTALL], [test "$vpath_install" = "yes"])
60
61AC_ARG_ENABLE(srp,
62       AS_HELP_STRING([--disable-srp],
63               [unconditionally disable the SRP functionality]),
64       use_srp=$enableval, use_srp=yes)
65
66# check if the available GnuTLS library supports SRP
67AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"])
68
69GNUTLS_FEAT_CFLAGS=""
70if test "$use_srp" != "no"; then
71        GNUTLS_FEAT_CFLAGS="-DENABLE_SRP=1"
72fi
73
74# check if the available GnuTLS library supports raw extension parsing
75AC_SEARCH_LIBS([gnutls_ext_raw_parse], [gnutls], [early_sni="yes"],
76        [early_sni="no"])
77if test "$early_sni" != "no"; then
78        ENABLE_EARLY_SNI=1
79        # This is for the test server configuration
80        EXPECT_EARLY_SNI="Define EXPECT_EARLY_SNI"
81else
82        ENABLE_EARLY_SNI=0
83        EXPECT_EARLY_SNI=""
84fi
85AC_SUBST(ENABLE_EARLY_SNI)
86AC_SUBST(EXPECT_EARLY_SNI)
87AM_SUBST_NOTMAKE(EXPECT_EARLY_SNI)
88
89AC_ARG_ENABLE(strict,
90       AS_HELP_STRING([--disable-strict],
91               [Avoid strict compiler warnings and errors]),
92       use_strict=$enableval, use_strict=yes)
93
94STRICT_CFLAGS=""
95if test "$use_strict" != "no"; then
96        STRICT_CFLAGS="-Wall -Werror -Wextra -Wno-error=deprecated-declarations"
97fi
98
99AC_MSG_CHECKING([whether to enable SRP functionality])
100AC_MSG_RESULT($use_srp)
101
102dnl Optionally disable flock
103AC_ARG_ENABLE(flock,
104        AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \
105        (some exotic architectures don't support it)]),
106        [use_flock=$enableval], [use_flock=yes])
107# Check if flock is available and supports --timeout
108AC_PATH_PROG([FLOCK], [flock], [no])
109AS_IF([test "${FLOCK}" != "no"],
110      [
111        AC_MSG_CHECKING([whether ${FLOCK} supports --timeout])
112        lockfile="$(mktemp)"
113        AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1],
114              [flock_works="yes"], [flock_works="no"])
115        AC_MSG_RESULT([$flock_works])
116        # Old versions of flock do not support --verbose. They fail
117        # without executing the command but still return 0. Check for
118        # this behavior by testing if the rm command was executed.
119        AC_MSG_CHECKING([whether ${FLOCK} supports --verbose])
120        testfile="$(mktemp)"
121        AS_IF([${FLOCK} --verbose --timeout 1 ${lockfile} rm "${testfile}" \
122                        >&AS_MESSAGE_LOG_FD 2>&1; test ! -e "${testfile}"],
123              [flock_verbose="yes"; FLOCK="${FLOCK} --verbose"],
124              [flock_verbose="no"; rm "${testfile}"])
125        AC_MSG_RESULT([$flock_verbose])
126        rm "${lockfile}"
127      ],
128      [flock_works="no"])
129# disable flock if requested by user or it doesn't support timeout
130AM_CONDITIONAL([DISABLE_FLOCK],
131               [test "$enable_flock" = "no" || test "$flock_works" = "no"])
132
133# openssl is needed as the responder for OCSP tests
134AC_PATH_PROG([OPENSSL], [openssl], [no])
135AM_CONDITIONAL([ENABLE_OCSP_TEST], [test "${OPENSSL}" != "no"])
136
137dnl Enable test namespaces? Default is "yes".
138AC_ARG_ENABLE(test-namespaces,
139        AS_HELP_STRING([--disable-test-namespaces], [Disable use of \
140        namespaces for tests (limits parallelization)]),
141        [use_netns=$enableval], [use_netns=yes])
142
143# Check if "unshare" is available and has permission to create
144# network, IPC, and user namespaces
145AC_PATH_PROG([UNSHARE], [unshare], [no])
146AS_IF([test "${UNSHARE}" != "no"],
147      [
148        AC_MSG_CHECKING([for permission to use namespaces])
149        AS_IF([${UNSHARE} --net --ipc -r /bin/sh -c \
150                "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1],
151              [unshare_works="yes"], [unshare_works="no"])
152        AC_MSG_RESULT([$unshare_works])
153      ],
154      [unshare_works="no"])
155# decide whether to enable network namespaces
156AS_IF([test "$enable_test_namespaces" != "no" \
157            && test "$unshare_works" = "yes"],
158      [use_netns="yes"], [use_netns="no"])
159AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"])
160# Adjust Apache configuration for tests accordingly: Use pthread mutex
161# and test specific PID files if using namespaces, defaults otherwise.
162AS_IF([test "$use_netns" = "yes"],
163      [MUTEX_CONF="Mutex pthread default"; PID_AFFIX="-\${TEST_NAME}"],
164      [MUTEX_CONF=""; PID_AFFIX=""])
165AC_SUBST(MUTEX_CONF)
166AC_SUBST(PID_AFFIX)
167AM_SUBST_NOTMAKE(MUTEX_CONF)
168AM_SUBST_NOTMAKE(PID_AFFIX)
169
170AC_ARG_ENABLE(msva,
171       AS_HELP_STRING([--enable-msva],
172               [enable Monkeysphere client certificate verification]),
173       use_msva=$enableval, use_msva=no)
174AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"])
175
176MSVA_CFLAGS=""
177if test "$use_msva" != "no"; then
178        AC_CHECK_HEADERS([msv/msv.h], [],
179                         [AC_MSG_ERROR([*** No libmsv headers found!])])
180        AC_SEARCH_LIBS([msv_query_agent], [msv], [],
181                         [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])])
182        MSVA_CFLAGS="-DENABLE_MSVA=1"
183fi
184
185AC_MSG_CHECKING([whether to enable MSVA functionality])
186AC_MSG_RESULT($use_msva)
187
188# Building documentation requires pandoc, which in turn needs pdflatex
189# to build PDF output.
190build_doc=no
191AC_PATH_PROG([PANDOC], [pandoc], [no])
192if test "$PANDOC" != "no"; then
193        AC_PATH_PROG([PDFLATEX], [pdflatex], [no])
194        if test "$PDFLATEX" != "no"; then
195                build_doc="html, manual page, pdf"
196        else
197                build_doc="html, manual page"
198        fi
199else
200        AC_PATH_PROG([MARKDOWN], [markdown], [no])
201        if test "$MARKDOWN" != "no"; then
202                build_doc="html stub"
203        fi
204fi
205AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"])
206AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \
207                               test "$PDFLATEX" != "no"])
208AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \
209                               test "$MARKDOWN" != "no"])
210
211# Check for Apache binary
212AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin])
213if test "${APACHE2}" = "no"; then
214        AC_MSG_WARN([Neither apache2 nor httpd found in \
215                     PATH. Test suite will fail.])
216fi
217
218AC_PATH_PROGS([HTTP_CLI], [curl wget], [no])
219
220MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${GNUTLS_FEAT_CFLAGS} ${MSVA_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}"
221MODULE_LIBS="${LIBGNUTLS_LIBS}"
222
223AC_PATH_PROGS([SOFTHSM], [softhsm2-util softhsm], [no])
224if test "${SOFTHSM}" != "no"; then
225        softhsm_version=$(${SOFTHSM} --version)
226        AS_VERSION_COMPARE([$(${SOFTHSM} --version)], [2.0.0],
227                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [1])],
228                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])],
229                           [AC_SUBST(SOFTHSM_MAJOR_VERSION, [2])])
230fi
231AM_CONDITIONAL([HAVE_SOFTHSM], [test "${SOFTHSM}" != "no"])
232AM_CONDITIONAL([HAVE_SOFTHSM1], [test "${SOFTHSM_MAJOR_VERSION}" = "1"])
233AM_CONDITIONAL([HAVE_SOFTHSM2], [test "${SOFTHSM_MAJOR_VERSION}" = "2"])
234
235AC_SUBST(MODULE_CFLAGS)
236AC_SUBST(MODULE_LIBS)
237
238# assign default values to TEST_HOST and TEST_IP if necessary
239: ${TEST_HOST:="localhost"}
240: ${TEST_IP:="[[::1]] 127.0.0.1"}
241AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \
242                        "make check", must resolve to addresses in TEST_IP. \
243                        The default is "localhost".])
244AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \
245                      started by "make check". The default is \
246                      "[::1] 127.0.0.1". Note that IPv6 addresses must be \
247                      enclosed in square brackets.])
248
249: ${TEST_LOCK_WAIT:="30"}
250: ${TEST_QUERY_TIMEOUT:="30"}
251AC_ARG_VAR([TEST_LOCK_WAIT], [Timeout in seconds to acquire locks for \
252                             Apache instances in the test suite, or the \
253                             previous instance to remove its PID file if \
254                             flock is not used. Default is 30.])
255AC_ARG_VAR([TEST_QUERY_TIMEOUT], [Timeout in seconds for HTTPS requests \
256                                 sent using gnutls-cli in the test suite. \
257                                 Default is 30.])
258
259dnl Allow user to set SoftHSM PKCS #11 module
260AC_ARG_VAR([SOFTHSM_LIB], [Absolute path of the SoftHSM PKCS @%:@11 module to \
261                          use. By default the test suite will search common \
262                          library paths.])
263
264dnl Build list of "Listen" statements for Apache
265LISTEN_LIST="@%:@ Listen addresses for the test servers"
266for i in ${TEST_IP}; do
267        LISTEN_LIST="${LISTEN_LIST}
268Listen ${i}:\${TEST_PORT}"
269done
270# Available extra ports, tests can "Define" variables of the listed
271# names in their apache.conf to enable them.
272for j in TEST_HTTP_PORT; do
273LISTEN_LIST="${LISTEN_LIST}
274<IfDefine ${j}>"
275for i in ${TEST_IP}; do
276        LISTEN_LIST="${LISTEN_LIST}
277        Listen ${i}:\${${j}}"
278done
279LISTEN_LIST="${LISTEN_LIST}
280</IfDefine>"
281done
282AC_SUBST(LISTEN_LIST)
283AM_SUBST_NOTMAKE(LISTEN_LIST)
284
285DX_DOXYGEN_FEATURE(ON)
286DX_DOT_FEATURE(ON)
287DX_HTML_FEATURE(ON)
288DX_MAN_FEATURE(OFF)
289DX_RTF_FEATURE(OFF)
290DX_XML_FEATURE(OFF)
291DX_PDF_FEATURE(OFF)
292DX_PS_FEATURE(OFF)
293DX_INIT_DOXYGEN([mod_gnutls], [doc/doxygen.conf], [doc/api])
294
295AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \
296                        doc/Makefile doc/doxygen.conf include/mod_gnutls.h \
297                        test/proxy_backend.conf test/ocsp_server.conf \
298                        test/apache-conf/early_sni.conf \
299                        test/apache-conf/listen.conf \
300                        test/apache-conf/netns.conf])
301AC_OUTPUT
302
303echo "---"
304echo "Configuration summary for mod_gnutls:"
305echo ""
306echo "   * mod_gnutls version:  ${MOD_GNUTLS_VERSION}"
307echo "   * Apache Modules directory:    ${AP_LIBEXECDIR}"
308echo "   * GnuTLS Library version:      ${LIBGNUTLS_VERSION}"
309echo "   * CFLAGS for GnuTLS:           ${LIBGNUTLS_CFLAGS}"
310echo "   * LDFLAGS for GnuTLS:  ${LIBGNUTLS_LIBS}"
311echo "   * SRP Authentication:  ${use_srp}"
312echo "   * MSVA Client Verification:    ${use_msva}"
313echo "   * Early SNI:                   ${early_sni}"
314echo "   * Build documentation: ${build_doc}"
315echo ""
316echo "---"
Note: See TracBrowser for help on using the repository browser.