source: mod_gnutls/configure.ac @ f0923c4

debian/masterdebian/stretch-backportsjessie-backportsupstream mod_gnutls/0.7.3
Last change on this file since f0923c4 was f0923c4, checked in by Thomas Klute <thomas2.klute@…>, 4 years ago

Release version 0.7.3

  • Property mode set to 100644
File size: 7.0 KB
Line 
1dnl
2AC_INIT(mod_gnutls, 0.7.3)
3OOO_CONFIG_NICE(config.nice)
4MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION
5AC_PREREQ(2.53)
6AC_CONFIG_SRCDIR([src/mod_gnutls.c])
7AC_CONFIG_AUX_DIR(config)
8
9OOO_MAINTAIN_MODE
10AM_MAINTAINER_MODE
11AC_CANONICAL_TARGET
12# mod_gnutls test suite requires GNU make
13AM_INIT_AUTOMAKE([-Wno-portability])
14AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in)
15
16AC_SUBST(MOD_GNUTLS_VERSION)
17
18AC_PROG_CC
19AC_PROG_CC_C99
20AC_PROG_LD
21AC_PROG_INSTALL
22AC_PROG_LIBTOOL
23
24AC_CONFIG_MACRO_DIR([m4])
25
26AP_VERSION=2.2.0
27CHECK_APACHE(,$AP_VERSION,
28    :,:,
29    AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
30)
31
32PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.4])
33
34LIBGNUTLS_VERSION=`pkg-config --modversion gnutls`
35
36AC_ARG_ENABLE(srp,
37       AS_HELP_STRING([--disable-srp],
38               [unconditionally disable the SRP functionality]),
39       use_srp=$enableval, use_srp=yes)
40
41# check if the available GnuTLS library supports SRP
42AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"])
43
44SRP_CFLAGS=""
45if test "$use_srp" != "no"; then
46        SRP_CFLAGS="-DENABLE_SRP=1"
47fi
48
49AC_ARG_ENABLE(strict,
50       AS_HELP_STRING([--disable-strict],
51               [Avoid strict compiler warnings and errors]),
52       use_strict=$enableval, use_strict=yes)
53
54STRICT_CFLAGS=""
55if test "$use_strict" != "no"; then
56        STRICT_CFLAGS="-Wall -Werror -Wextra"
57fi
58
59AC_MSG_CHECKING([whether to enable SRP functionality])
60AC_MSG_RESULT($use_srp)
61
62dnl Optionally disable flock
63AC_ARG_ENABLE(flock,
64        AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \
65        (some exotic architectures don't support it)]),
66        [use_flock=$enableval], [use_flock=yes])
67# Check if flock is available and supports --timeout
68AC_PATH_PROG([FLOCK], [flock], [no])
69AS_IF([test "${FLOCK}" != "no"],
70      [
71        AC_MSG_CHECKING([whether ${FLOCK} supports --timeout])
72        lockfile="$(mktemp)"
73        AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1],
74              [flock_works="yes"], [flock_works="no"])
75        rm "${lockfile}"
76        AC_MSG_RESULT([$flock_works])
77      ],
78      [flock_works="no"])
79# disable flock if requested by user or it doesn't support timeout
80AM_CONDITIONAL([DISABLE_FLOCK],
81               [test "$enable_flock" = "no" || test "$flock_works" = "no"])
82
83dnl Enable test namespaces? Default is "yes".
84AC_ARG_ENABLE(test-namespaces,
85        AS_HELP_STRING([--disable-test-namespaces], [Disable use of network \
86        namespaces to run tests in parallel (some architectures might not \
87        support it)]),
88        [use_netns=$enableval], [use_netns=yes])
89
90# Check if "unshare" is available and has permission to create network
91# and user namespaces
92AC_PATH_PROG([UNSHARE], [unshare], [no])
93AS_IF([test "${UNSHARE}" != "no"],
94      [
95        AC_MSG_CHECKING([for permission to create network and user namespaces])
96        AS_IF([${UNSHARE} --net -r /bin/sh -c \
97                "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1],
98              [unshare_works="yes"], [unshare_works="no"])
99        AC_MSG_RESULT([$unshare_works])
100      ],
101      [unshare_works="no"])
102# decide whether to enable network namespaces
103AS_IF([test "$enable_test_namespaces" != "no" \
104            && test "$unshare_works" = "yes"],
105      [use_netns="yes"], [use_netns="no"])
106AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"])
107# Adjust Apache configuration for tests accordingly: Use pthread mutex
108# and test specific PID files if using namespaces, defaults otherwise.
109AS_IF([test "$use_netns" = "yes"],
110      [MUTEX_TYPE="pthread"; PID_AFFIX="-\${TEST_NAME}"],
111      [MUTEX_TYPE="default"; PID_AFFIX=""])
112AC_SUBST(MUTEX_TYPE)
113AC_SUBST(PID_AFFIX)
114AM_SUBST_NOTMAKE(MUTEX_TYPE)
115AM_SUBST_NOTMAKE(PID_AFFIX)
116
117AC_ARG_ENABLE(msva,
118       AS_HELP_STRING([--enable-msva],
119               [enable Monkeysphere client certificate verification]),
120       use_msva=$enableval, use_msva=no)
121AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"])
122
123MSVA_CFLAGS=""
124if test "$use_msva" != "no"; then
125        AC_CHECK_HEADERS([msv/msv.h], [],
126                         [AC_MSG_ERROR([*** No libmsv headers found!])])
127        AC_SEARCH_LIBS([msv_query_agent], [msv], [],
128                         [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])])
129        MSVA_CFLAGS="-DENABLE_MSVA=1"
130fi
131
132AC_MSG_CHECKING([whether to enable MSVA functionality])
133AC_MSG_RESULT($use_msva)
134
135have_apr_memcache=0
136CHECK_APR_MEMCACHE([have_apr_memcache=1], [have_apr_memcache=0])
137AC_SUBST(have_apr_memcache)
138
139# Building documentation requires pandoc, which in turn needs pdflatex
140# to build PDF output.
141build_doc=no
142AC_PATH_PROG([PANDOC], [pandoc], [no])
143if test "$PANDOC" != "no"; then
144        AC_PATH_PROG([PDFLATEX], [pdflatex], [no])
145        if test "$PDFLATEX" != "no"; then
146                build_doc=yes
147        else
148                build_doc="html only"
149        fi
150else
151        AC_PATH_PROG([MARKDOWN], [markdown], [no])
152        if test "$MARKDOWN" != "no"; then
153                build_doc="html stub"
154        fi
155fi
156AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"])
157AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \
158                               test "$PDFLATEX" != "no"])
159AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \
160                               test "$MARKDOWN" != "no"])
161
162# Check for Apache binary
163AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin])
164if test "${APACHE2}" = "no"; then
165        AC_MSG_WARN([Neither apache2 nor httpd found in \
166                     PATH. Test suite will fail.])
167fi
168
169AC_PATH_PROGS([HTTP_CLI], [curl wget], [no])
170
171MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${SRP_CFLAGS} ${MSVA_CFLAGS} ${APR_MEMCACHE_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}"
172MODULE_LIBS="${APR_MEMCACHE_LIBS} ${LIBGNUTLS_LIBS}"
173
174AC_SUBST(MODULE_CFLAGS)
175AC_SUBST(MODULE_LIBS)
176
177# assign default values to TEST_HOST and TEST_IP if necessary
178: ${TEST_HOST:="localhost"}
179: ${TEST_IP:="[[::1]] 127.0.0.1"}
180AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \
181                        "make check", must resolve to addresses in TEST_IP. \
182                        The default is "localhost".])
183AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \
184                      started by "make check". The default is \
185                      "[::1] 127.0.0.1". Note that IPv6 addresses must be \
186                      enclosed in square brackets.])
187AM_SUBST_NOTMAKE(TEST_IP)
188
189dnl Build list of "Listen" statements for Apache
190LISTEN_LIST="# Listen addresses for the test servers"
191for i in ${TEST_IP}; do
192        LISTEN_LIST="${LISTEN_LIST}
193Listen ${i}:\${TEST_PORT}"
194done
195dnl HTTP ports, only active if TEST_HTTP_PORT is defined
196LISTEN_LIST="${LISTEN_LIST}
197<IfDefine TEST_HTTP_PORT>"
198for i in ${TEST_IP}; do
199        LISTEN_LIST="${LISTEN_LIST}
200        Listen ${i}:\${TEST_HTTP_PORT}"
201done
202LISTEN_LIST="${LISTEN_LIST}
203</IfDefine>"
204AC_SUBST(LISTEN_LIST)
205AM_SUBST_NOTMAKE(LISTEN_LIST)
206
207AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \
208                        doc/Makefile include/mod_gnutls.h \
209                        test/proxy_backend.conf \
210                        test/apache-conf/listen.conf \
211                        test/apache-conf/netns.conf])
212AC_OUTPUT
213
214echo "---"
215echo "Configuration summary for mod_gnutls:"
216echo ""
217echo "   * mod_gnutls version:  ${MOD_GNUTLS_VERSION}"
218echo "   * Apache Modules directory:    ${AP_LIBEXECDIR}"
219echo "   * GnuTLS Library version:      ${LIBGNUTLS_VERSION}"
220echo "   * SRP Authentication:  ${use_srp}"
221echo "   * MSVA Client Verification:    ${use_msva}"
222echo "   * Build documentation: ${build_doc}"
223echo ""
224echo "---"
Note: See TracBrowser for help on using the repository browser.