source: mod_gnutls/configure.ac @ fe3564a

asyncioproxy-ticket
Last change on this file since fe3564a was fe3564a, checked in by Fiona Klute <fiona.klute@…>, 12 months ago

configure.as: Use AS_IF instead of shell if-blocks around macros

Some macros can have weird side effects inside shell if-blocks. I
haven't seen problems with the ones here, but it's still better to
clean up.

  • Property mode set to 100644
File size: 10.3 KB
Line 
1AC_INIT(mod_gnutls, 0.10.0)
2OOO_CONFIG_NICE(config.nice)
3MOD_GNUTLS_VERSION=AC_PACKAGE_VERSION
4AC_PREREQ(2.53)
5AC_CONFIG_SRCDIR([src/mod_gnutls.c])
6AC_CONFIG_AUX_DIR(config)
7
8OOO_MAINTAIN_MODE
9AM_MAINTAINER_MODE
10AC_CANONICAL_TARGET
11# mod_gnutls test suite requires GNU make
12AM_INIT_AUTOMAKE([-Wno-portability])
13AM_CONFIG_HEADER(include/mod_gnutls_config.h:config.in)
14
15LT_INIT([disable-static])
16
17AC_SUBST(MOD_GNUTLS_VERSION)
18
19AC_PROG_CC
20AC_PROG_CC_C99
21AC_PROG_LD
22AC_PROG_INSTALL
23AC_PROG_LIBTOOL
24
25AC_CONFIG_MACRO_DIR([m4])
26
27AP_VERSION=2.4.17
28CHECK_APACHE(,$AP_VERSION,
29    :,:,
30    AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
31)
32
33dnl Maybe use the binaries for tests, too?
34AC_ARG_WITH([gnutls-dev],
35        AS_HELP_STRING([--with-gnutls-dev=DIR],
36                [Use GnuTLS libraries from a development (git) tree. Use \
37                this if you want to test mod_gnutls with the latest \
38                GnuTLS code.]),
39        [
40                AS_IF([test -d "${with_gnutls_dev}" ],
41                [
42                        LIBGNUTLS_CFLAGS="-I${with_gnutls_dev}/lib/includes"
43                        LIBGNUTLS_LIBS="-lgnutls -L${with_gnutls_dev}/lib/.libs -R${with_gnutls_dev}/lib/.libs"
44                ],
45                [AC_MSG_ERROR([--with-gnutls-dev=DIR requires a directory!])])
46        ], [])
47
48PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.6.3])
49
50LIBGNUTLS_VERSION=`pkg-config --modversion gnutls`
51
52AC_ARG_ENABLE(vpath-install,
53       AS_HELP_STRING([--enable-vpath-install],
54               [Modify the Apache module directory provided by apxs to \
55               follow --prefix, if necessary. Most users will not want this, \
56               but it is required for VPATH builds including "make \
57               distcheck".]),
58       vpath_install=$enableval, vpath_install=no)
59AM_CONDITIONAL([ENABLE_VPATH_INSTALL], [test "$vpath_install" = "yes"])
60
61AC_ARG_ENABLE(srp,
62       AS_HELP_STRING([--disable-srp],
63               [unconditionally disable the SRP functionality]),
64       use_srp=$enableval, use_srp=yes)
65
66# check if the available GnuTLS library supports SRP
67AC_SEARCH_LIBS([gnutls_srp_server_get_username], [gnutls], [], [use_srp="no"])
68
69GNUTLS_FEAT_CFLAGS=""
70if test "$use_srp" != "no"; then
71        GNUTLS_FEAT_CFLAGS="-DENABLE_SRP=1"
72fi
73
74AC_ARG_ENABLE(strict,
75       AS_HELP_STRING([--disable-strict],
76               [Avoid strict compiler warnings and errors]),
77       use_strict=$enableval, use_strict=yes)
78
79STRICT_CFLAGS=""
80if test "$use_strict" != "no"; then
81        STRICT_CFLAGS="-Wall -Werror -Wextra -Wno-error=deprecated-declarations"
82fi
83
84AC_MSG_CHECKING([whether to enable SRP functionality])
85AC_MSG_RESULT($use_srp)
86
87AM_PATH_PYTHON([3])
88AX_PYTHON_MODULE([yaml], [fatal])
89
90dnl Enable testing with Valgrind? Default is "no".
91AC_ARG_ENABLE([valgrind-test],
92        AS_HELP_STRING([--enable-valgrind-test], [Enable running \
93        tests with Valgrind (slow)]),
94        [use_valgrind=$enableval], [use_valgrind=no])
95AC_MSG_CHECKING([whether to run tests with Valgrind])
96AC_MSG_RESULT([$use_valgrind])
97AC_PATH_PROG([VALGRIND], [valgrind], [no])
98AS_IF([test "${use_valgrind}" != "no" -a "${VALGRIND}" = "no"],
99      [AC_MSG_ERROR([Valgrind test are enabled, but "valgrind" not \
100      found in PATH!])])
101AM_CONDITIONAL([ENABLE_VALGRIND], [test "${use_valgrind}" != "no"])
102
103dnl Optionally disable flock
104AC_ARG_ENABLE(flock,
105        AS_HELP_STRING([--disable-flock], [Disable use of flock during tests \
106        (some exotic architectures don't support it)]),
107        [use_flock=$enableval], [use_flock=yes])
108# Check if flock is available and supports --timeout
109AC_PATH_PROG([FLOCK], [flock], [no])
110AS_IF([test "${FLOCK}" != "no"],
111      [
112        AC_MSG_CHECKING([whether ${FLOCK} supports --timeout])
113        lockfile="$(mktemp)"
114        AS_IF([${FLOCK} --timeout 1 ${lockfile} true >&AS_MESSAGE_LOG_FD 2>&1],
115              [flock_works="yes"], [flock_works="no"])
116        AC_MSG_RESULT([$flock_works])
117        # Old versions of flock do not support --verbose. They fail
118        # without executing the command but still return 0. Check for
119        # this behavior by testing if the rm command was executed.
120        AC_MSG_CHECKING([whether ${FLOCK} supports --verbose])
121        testfile="$(mktemp)"
122        AS_IF([${FLOCK} --verbose --timeout 1 ${lockfile} rm "${testfile}" \
123                        >&AS_MESSAGE_LOG_FD 2>&1; test ! -e "${testfile}"],
124              [flock_verbose="yes"; FLOCK="${FLOCK} --verbose"],
125              [flock_verbose="no"; rm "${testfile}"])
126        AC_MSG_RESULT([$flock_verbose])
127        rm "${lockfile}"
128      ],
129      [flock_works="no"])
130# disable flock if requested by user or it doesn't support timeout
131AM_CONDITIONAL([DISABLE_FLOCK],
132               [test "$enable_flock" = "no" || test "$flock_works" = "no"])
133
134# openssl is needed as the responder for OCSP tests
135AC_PATH_PROG([OPENSSL], [openssl], [no])
136AM_CONDITIONAL([ENABLE_OCSP_TEST], [test "${OPENSSL}" != "no"])
137
138dnl Enable test namespaces? Default is "yes".
139AC_ARG_ENABLE(test-namespaces,
140        AS_HELP_STRING([--disable-test-namespaces], [Disable use of \
141        namespaces for tests (limits parallelization)]),
142        [use_netns=$enableval], [use_netns=yes])
143
144# Check if "unshare" is available and has permission to create
145# network, IPC, and user namespaces
146AC_PATH_PROG([UNSHARE], [unshare], [no])
147AS_IF([test "${UNSHARE}" != "no"],
148      [
149        AC_MSG_CHECKING([for permission to use namespaces])
150        AS_IF([${UNSHARE} --net --ipc -r /bin/sh -c \
151                "ip link set up lo && ip addr show" >&AS_MESSAGE_LOG_FD 2>&1],
152              [unshare_works="yes"], [unshare_works="no"])
153        AC_MSG_RESULT([$unshare_works])
154      ],
155      [unshare_works="no"])
156# decide whether to enable network namespaces
157AS_IF([test "$enable_test_namespaces" != "no" \
158            && test "$unshare_works" = "yes"],
159      [use_netns="yes"], [use_netns="no"])
160AM_CONDITIONAL([ENABLE_NETNS], [test "$use_netns" != "no"])
161# Adjust Apache configuration for tests accordingly: Use pthread mutex
162# and test specific PID files if using namespaces, defaults otherwise.
163AS_IF([test "$use_netns" = "yes"],
164      [MUTEX_CONF="Mutex pthread default"; PID_AFFIX="-\${TEST_NAME}"],
165      [MUTEX_CONF=""; PID_AFFIX=""])
166AC_SUBST(MUTEX_CONF)
167AC_SUBST(PID_AFFIX)
168AM_SUBST_NOTMAKE(MUTEX_CONF)
169AM_SUBST_NOTMAKE(PID_AFFIX)
170
171AC_ARG_ENABLE(msva,
172       AS_HELP_STRING([--enable-msva],
173               [enable Monkeysphere client certificate verification]),
174       use_msva=$enableval, use_msva=no)
175AM_CONDITIONAL([USE_MSVA], [test "$use_msva" != "no"])
176
177MSVA_CFLAGS=""
178AS_IF([test "$use_msva" != "no"], [
179        AC_CHECK_HEADERS([msv/msv.h], [],
180                         [AC_MSG_ERROR([*** No libmsv headers found!])])
181        AC_SEARCH_LIBS([msv_query_agent], [msv], [],
182                         [AC_MSG_ERROR([*** No libmsv found with msv_query_agent!])])
183        MSVA_CFLAGS="-DENABLE_MSVA=1"
184])
185
186AC_MSG_CHECKING([whether to enable MSVA functionality])
187AC_MSG_RESULT($use_msva)
188
189# Building documentation requires pandoc, which in turn needs pdflatex
190# to build PDF output.
191build_doc=no
192AC_PATH_PROG([PANDOC], [pandoc], [no])
193AS_IF([test "$PANDOC" != "no"], [
194        AC_PATH_PROG([PDFLATEX], [pdflatex], [no])
195        if test "$PDFLATEX" != "no"; then
196                build_doc="html, manual page, pdf"
197        else
198                build_doc="html, manual page"
199        fi
200], [
201        AC_PATH_PROG([MARKDOWN], [markdown], [no])
202        if test "$MARKDOWN" != "no"; then
203                build_doc="html stub"
204        fi
205])
206AM_CONDITIONAL([USE_PANDOC], [test "$PANDOC" != "no"])
207AM_CONDITIONAL([USE_PDFLATEX], [test "$PANDOC" != "no" && \
208                               test "$PDFLATEX" != "no"])
209AM_CONDITIONAL([USE_MARKDOWN], [test -n "$MARKDOWN" && \
210                               test "$MARKDOWN" != "no"])
211
212# Check for Apache binary
213AC_PATH_PROGS([APACHE2], [apache2 httpd], [no], [$PATH:/usr/sbin])
214AS_IF([test "${APACHE2}" = "no"], [
215        AC_MSG_WARN([Neither apache2 nor httpd found in \
216                     PATH. Test suite will fail.])
217])
218
219AC_PATH_PROGS([HTTP_CLI], [curl], [no])
220
221MODULE_CFLAGS="${LIBGNUTLS_CFLAGS} ${GNUTLS_FEAT_CFLAGS} ${MSVA_CFLAGS} ${APXS_CFLAGS} ${AP_INCLUDES} ${APR_INCLUDES} ${APU_INCLUDES} ${STRICT_CFLAGS}"
222MODULE_LIBS="${LIBGNUTLS_LIBS}"
223
224AC_PATH_PROGS([SOFTHSM], [softhsm2-util], [no])
225AM_CONDITIONAL([HAVE_SOFTHSM], [test "${SOFTHSM}" != "no"])
226
227AC_SUBST(MODULE_CFLAGS)
228AC_SUBST(MODULE_LIBS)
229
230# assign default values to TEST_HOST and TEST_IP if necessary
231: ${TEST_HOST:="localhost"}
232: ${TEST_IP:="[[::1]] 127.0.0.1"}
233AC_ARG_VAR([TEST_HOST], [Host name to use for server instances started by \
234                        "make check", must resolve to addresses in TEST_IP. \
235                        The default is "localhost".])
236AC_ARG_VAR([TEST_IP], [List of IP addresses to use for server instances \
237                      started by "make check". The default is \
238                      "[::1] 127.0.0.1". Note that IPv6 addresses must be \
239                      enclosed in square brackets.])
240
241: ${TEST_LOCK_WAIT:="30"}
242: ${TEST_QUERY_TIMEOUT:="30"}
243AC_ARG_VAR([TEST_LOCK_WAIT], [Timeout in seconds to acquire locks for \
244                             Apache instances in the test suite, or the \
245                             previous instance to remove its PID file if \
246                             flock is not used. Default is 30.])
247AC_ARG_VAR([TEST_QUERY_TIMEOUT], [Timeout in seconds for HTTPS requests \
248                                 sent using gnutls-cli in the test suite. \
249                                 Default is 30.])
250
251dnl Allow user to set SoftHSM PKCS #11 module
252AC_ARG_VAR([SOFTHSM_LIB], [Absolute path of the SoftHSM PKCS @%:@11 module to \
253                          use. By default the test suite will search common \
254                          library paths.])
255
256dnl Build list of "Listen" statements for Apache
257LISTEN_LIST="@%:@ Listen addresses for the test servers"
258for i in ${TEST_IP}; do
259        LISTEN_LIST="${LISTEN_LIST}
260Listen ${i}:\${TEST_PORT}"
261done
262# Available extra ports, tests can "Define" variables of the listed
263# names in their apache.conf to enable them.
264for j in TEST_HTTP_PORT; do
265LISTEN_LIST="${LISTEN_LIST}
266<IfDefine ${j}>"
267for i in ${TEST_IP}; do
268        LISTEN_LIST="${LISTEN_LIST}
269        Listen ${i}:\${${j}}"
270done
271LISTEN_LIST="${LISTEN_LIST}
272</IfDefine>"
273done
274AC_SUBST(LISTEN_LIST)
275AM_SUBST_NOTMAKE(LISTEN_LIST)
276
277DX_DOXYGEN_FEATURE(ON)
278DX_DOT_FEATURE(ON)
279DX_HTML_FEATURE(ON)
280DX_MAN_FEATURE(OFF)
281DX_RTF_FEATURE(OFF)
282DX_XML_FEATURE(OFF)
283DX_PDF_FEATURE(OFF)
284DX_PS_FEATURE(OFF)
285DX_INIT_DOXYGEN([mod_gnutls], [doc/doxygen.conf], [doc/api])
286
287AC_CONFIG_FILES([Makefile src/Makefile test/Makefile test/tests/Makefile \
288                        doc/Makefile doc/doxygen.conf include/mod_gnutls.h \
289                        test/proxy_backend.conf test/ocsp_server.conf \
290                        test/apache-conf/listen.conf \
291                        test/apache-conf/netns.conf])
292AC_OUTPUT
293
294echo "---"
295echo "Configuration summary for mod_gnutls:"
296echo ""
297echo "   * mod_gnutls version:  ${MOD_GNUTLS_VERSION}"
298echo "   * Apache Modules directory:    ${AP_LIBEXECDIR}"
299echo "   * GnuTLS Library version:      ${LIBGNUTLS_VERSION}"
300echo "   * CFLAGS for GnuTLS:           ${LIBGNUTLS_CFLAGS}"
301echo "   * LDFLAGS for GnuTLS:  ${LIBGNUTLS_LIBS}"
302echo "   * SRP Authentication:  ${use_srp}"
303echo "   * MSVA Client Verification:    ${use_msva}"
304echo "   * Build documentation: ${build_doc}"
305echo ""
306echo "---"
Note: See TracBrowser for help on using the repository browser.